From c0d4dcc6fdb183b8fbf087835bf6e51b4b8cff28 Mon Sep 17 00:00:00 2001
From: Pablo Ovelleiro Corral <mail@pablo.tools>
Date: Tue, 19 Nov 2024 11:48:36 +0100
Subject: [PATCH] ente-web: init at 0.9.16

---
 pkgs/by-name/en/ente-web/package.nix | 59 ++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)
 create mode 100644 pkgs/by-name/en/ente-web/package.nix

diff --git a/pkgs/by-name/en/ente-web/package.nix b/pkgs/by-name/en/ente-web/package.nix
new file mode 100644
index 000000000000..53faf8188dcb
--- /dev/null
+++ b/pkgs/by-name/en/ente-web/package.nix
@@ -0,0 +1,59 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  fetchYarnDeps,
+  nodejs,
+  yarnConfigHook,
+  yarnBuildHook,
+  extraBuildEnv ? { },
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "ente-web";
+  version = "0.9.16";
+
+  src = fetchFromGitHub {
+    owner = "ente-io";
+    repo = "ente";
+    sparseCheckout = [ "web" ];
+    rev = "refs/tags/photos-v${finalAttrs.version}";
+    fetchSubmodules = true;
+    hash = "sha256-DqfUUXY79CndEqPT8TR4PasLtaSCtqZaV2kp10Vu4PQ=";
+  };
+  sourceRoot = "${finalAttrs.src.name}/web";
+
+  offlineCache = fetchYarnDeps {
+    yarnLock = "${finalAttrs.src}/web/yarn.lock";
+    hash = "sha256-tgFh8Av1Wl77N4hR2Y5TQp9lEH4ZCQnCIWMPmlZBlV4=";
+  };
+
+  nativeBuildInputs = [
+    yarnConfigHook
+    yarnBuildHook
+    nodejs
+  ];
+
+  # See: https://github.com/ente-io/ente/blob/main/web/apps/photos/.env
+  env = extraBuildEnv;
+
+  installPhase = ''
+    runHook preInstall
+
+    cp -r apps/photos/out $out
+
+    runHook postInstall
+  '';
+
+  meta = {
+    description = "Web client for Ente Photos";
+    homepage = "https://ente.io/";
+    changelog = "https://github.com/ente-io/ente/releases";
+    license = lib.licenses.agpl3Only;
+    maintainers = with lib.maintainers; [
+      surfaceflinger
+      pinpox
+    ];
+    platforms = lib.platforms.all;
+  };
+})