From 8640fdd966826d3b4fc885289200afbad089424a Mon Sep 17 00:00:00 2001
From: ZHAO Jin-Xiang <xiaoxiangmoe@gmail.com>
Date: Sat, 20 Dec 2025 23:55:11 +0800
Subject: [PATCH] vscode-extensions.ms-vscode.js-debug-companion: init at 1.1.3

---
 .../editors/vscode/extensions/default.nix     |  2 +
 .../ms-vscode.js-debug-companion/default.nix  | 77 +++++++++++++++++++
 2 files changed, 79 insertions(+)
 create mode 100644 pkgs/applications/editors/vscode/extensions/ms-vscode.js-debug-companion/default.nix

diff --git a/pkgs/applications/editors/vscode/extensions/default.nix b/pkgs/applications/editors/vscode/extensions/default.nix
index 73878424cfc4..5a5744f0d127 100644
--- a/pkgs/applications/editors/vscode/extensions/default.nix
+++ b/pkgs/applications/editors/vscode/extensions/default.nix
@@ -3327,6 +3327,8 @@ let
         };
       };
 
+      ms-vscode.js-debug-companion = callPackage ./ms-vscode.js-debug-companion { };
+
       ms-vscode.hexeditor = buildVscodeMarketplaceExtension {
         mktplcRef = {
           publisher = "ms-vscode";
diff --git a/pkgs/applications/editors/vscode/extensions/ms-vscode.js-debug-companion/default.nix b/pkgs/applications/editors/vscode/extensions/ms-vscode.js-debug-companion/default.nix
new file mode 100644
index 000000000000..9c78beb483fc
--- /dev/null
+++ b/pkgs/applications/editors/vscode/extensions/ms-vscode.js-debug-companion/default.nix
@@ -0,0 +1,77 @@
+{
+  lib,
+  stdenvNoCC,
+  fetchFromGitHub,
+  fetchNpmDeps,
+  nodejs,
+  npmHooks,
+  vsce,
+  vscode-utils,
+  nix-update-script,
+}:
+
+let
+  vsix = stdenvNoCC.mkDerivation (finalAttrs: {
+    name = "vscode-js-debug-companion-${finalAttrs.version}.vsix";
+    pname = "vscode-js-debug-companion-vsix";
+    version = "1.1.3";
+
+    src = fetchFromGitHub {
+      owner = "microsoft";
+      repo = "vscode-js-debug-companion";
+      tag = "v${finalAttrs.version}";
+      hash = "sha256-+w6s6S1Vk99ABEJyQPEZXVPj0aNt6MvrD2nPGbxrsw0=";
+    };
+
+    npmDeps = fetchNpmDeps {
+      name = "${finalAttrs.pname}-npm-deps";
+      inherit (finalAttrs) src;
+      hash = "sha256-yirZRytdOYp7EMYIN6Yc7GC/9EFHONzarj+K/idj3pQ=";
+    };
+
+    nativeBuildInputs = [
+      nodejs
+      npmHooks.npmConfigHook
+      vsce
+    ];
+
+    strictDeps = true;
+
+    buildPhase = ''
+      runHook preBuild
+      vsce package
+      runHook postBuild
+    '';
+
+    installPhase = ''
+      runHook preInstall
+      cp ./js-debug-companion-$version.vsix $out
+      runHook postInstall
+    '';
+  });
+in
+vscode-utils.buildVscodeExtension (finalAttrs: {
+  pname = "vscode-js-debug-companion";
+  inherit (finalAttrs.src) version;
+
+  vscodeExtPublisher = "ms-vscode";
+  vscodeExtName = "js-debug-companion";
+  vscodeExtUniqueId = "${finalAttrs.vscodeExtPublisher}.${finalAttrs.vscodeExtName}";
+
+  src = vsix;
+
+  passthru = {
+    vsix = finalAttrs.src;
+    updateScript = nix-update-script {
+      attrPath = "vscode-extensions.ms-vscode.js-debug-companion.vsix";
+    };
+  };
+
+  meta = {
+    description = "Companion extension to js-debug that provides capability for remote debugging";
+    homepage = "https://github.com/microsoft/vscode-js-debug-companion";
+    downloadPage = "https://marketplace.visualstudio.com/items?itemName=ms-vscode.js-debug-companion";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ xiaoxiangmoe ];
+  };
+})