diff --git a/pkgs/by-name/pl/plik/package.nix b/pkgs/by-name/pl/plik/package.nix
new file mode 100644
index 000000000000..631bdb6b422b
--- /dev/null
+++ b/pkgs/by-name/pl/plik/package.nix
@@ -0,0 +1,32 @@
+{
+  buildGoModule,
+  plikd,
+}:
+
+buildGoModule (finalAttrs: {
+  pname = "plik";
+  inherit (plikd)
+    version
+    src
+    postPatch
+    passthru
+    ;
+
+  subPackages = [ "client" ];
+
+  vendorHash = null;
+
+  postInstall = ''
+    mv $out/bin/client $out/bin/plik
+  '';
+
+  meta = {
+    inherit (plikd.meta)
+      description
+      homepage
+      license
+      maintainers
+      ;
+    mainProgram = "plik";
+  };
+})
diff --git a/pkgs/by-name/pl/plikd/package.nix b/pkgs/by-name/pl/plikd/package.nix
new file mode 100644
index 000000000000..0e34e021a73d
--- /dev/null
+++ b/pkgs/by-name/pl/plikd/package.nix
@@ -0,0 +1,63 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+  fetchurl,
+  nixosTests,
+  makeWrapper,
+}:
+
+buildGoModule (finalAttrs: {
+  pname = "plikd";
+  version = "1.3.8";
+
+  src = fetchFromGitHub {
+    owner = "root-gg";
+    repo = "plik";
+    rev = finalAttrs.version;
+    hash = "sha256-WCtfkzlZnyzZDwNDBrW06bUbLYTL2C704Y7aXbiVi5c=";
+  };
+
+  # TODO build webapp from source (how to hanndle npm and bower deps?)
+  src-webapp = fetchurl {
+    url = "https://github.com/root-gg/plik/releases/download/${finalAttrs.version}/plik-${finalAttrs.version}-linux-amd64.tar.gz";
+    hash = "sha256-taUFXZJeUHYjjhrVlLgKYPxNn6W5o8uoEVcu+f5flCA=";
+  };
+
+  subPackages = [ "server" ];
+
+  vendorHash = null;
+
+  nativeBuildInputs = [
+    makeWrapper
+  ];
+
+  postPatch = ''
+    substituteInPlace server/common/version.go \
+      --replace '"0.0.0"' '"${finalAttrs.version}"'
+  '';
+
+  postInstall = ''
+    # install the webapp
+    mkdir -p $out/libexec/plikd/{bin,webapp} $out/bin
+    tar xf ${finalAttrs.src-webapp} plik-${finalAttrs.version}-linux-amd64/webapp/dist/
+    mv plik-*/webapp/dist $out/libexec/plikd/webapp
+
+    # move and wrap the server binary
+    mv $out/bin/server $out/libexec/plikd/bin/plikd
+    makeWrapper $out/libexec/plikd/bin/plikd $out/bin/plikd \
+      --chdir "$out/libexec/plikd/bin"
+  '';
+
+  passthru.tests = {
+    inherit (nixosTests) plikd;
+  };
+
+  meta = {
+    description = "Scalable & friendly temporary file upload system";
+    homepage = "https://plik.root.gg/";
+    license = lib.licenses.mit;
+    mainProgram = "plikd";
+    maintainers = [ ];
+  };
+})
diff --git a/pkgs/servers/plik/default.nix b/pkgs/servers/plik/default.nix
deleted file mode 100644
index dd0b0d7b446f..000000000000
--- a/pkgs/servers/plik/default.nix
+++ /dev/null
@@ -1,38 +0,0 @@
-{
-  lib,
-  fetchurl,
-  makeWrapper,
-  runCommand,
-  callPackage,
-}:
-
-let
-  version = "1.3.7";
-
-  programs = callPackage ./programs.nix { };
-
-  webapp = fetchurl {
-    url = "https://github.com/root-gg/plik/releases/download/${version}/plik-${version}-linux-amd64.tar.gz";
-    hash = "sha256-Uj3I/ohgMr/Ud5xAZiBjsIW8bSdUeXXv9NYKLu8Aym8=";
-  };
-
-in
-{
-
-  inherit (programs) plik plikd-unwrapped;
-
-  plikd =
-    runCommand "plikd-${version}"
-      {
-        nativeBuildInputs = [ makeWrapper ];
-        inherit (programs.plikd-unwrapped) passthru;
-      }
-      ''
-        mkdir -p $out/libexec/plikd/{bin,webapp} $out/bin
-        tar xf ${webapp} plik-${version}-linux-amd64/webapp/dist/
-        mv plik-*/webapp/dist $out/libexec/plikd/webapp
-        cp ${programs.plikd-unwrapped}/bin/plikd $out/libexec/plikd/bin/plikd
-        makeWrapper $out/libexec/plikd/bin/plikd $out/bin/plikd \
-          --chdir "$out/libexec/plikd/bin"
-      '';
-}
diff --git a/pkgs/servers/plik/programs.nix b/pkgs/servers/plik/programs.nix
deleted file mode 100644
index 66dae265238d..000000000000
--- a/pkgs/servers/plik/programs.nix
+++ /dev/null
@@ -1,74 +0,0 @@
-{
-  lib,
-  buildGoModule,
-  fetchFromGitHub,
-  makeWrapper,
-  runCommand,
-  nixosTests,
-}:
-
-let
-  version = "1.3.8";
-
-  src = fetchFromGitHub {
-    owner = "root-gg";
-    repo = "plik";
-    rev = version;
-    hash = "sha256-WCtfkzlZnyzZDwNDBrW06bUbLYTL2C704Y7aXbiVi5c=";
-  };
-
-  vendorHash = null;
-
-  meta = {
-    homepage = "https://plik.root.gg/";
-    description = "Scalable & friendly temporary file upload system";
-    maintainers = [ ];
-    license = lib.licenses.mit;
-    mainProgram = "plik";
-  };
-
-  postPatch = ''
-    substituteInPlace server/common/version.go \
-      --replace '"0.0.0"' '"${version}"'
-  '';
-
-  passthru.tests = {
-    inherit (nixosTests) plikd;
-  };
-
-in
-{
-
-  plik = buildGoModule {
-    pname = "plik";
-    inherit
-      version
-      meta
-      src
-      vendorHash
-      postPatch
-      passthru
-      ;
-
-    subPackages = [ "client" ];
-    postInstall = ''
-      mv $out/bin/client $out/bin/plik
-    '';
-  };
-
-  plikd-unwrapped = buildGoModule {
-    pname = "plikd-unwrapped";
-    inherit
-      version
-      src
-      vendorHash
-      postPatch
-      passthru
-      ;
-
-    subPackages = [ "server" ];
-    postFixup = ''
-      mv $out/bin/server $out/bin/plikd
-    '';
-  };
-}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index f9c943df90e8..321356f1ae1b 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -3334,11 +3334,6 @@ with pkgs;
   playwright-driver = (callPackage ../development/web/playwright/driver.nix { }).playwright-core;
   playwright-test = (callPackage ../development/web/playwright/driver.nix { }).playwright-test;
 
-  inherit (callPackage ../servers/plik { })
-    plik
-    plikd
-    ;
-
   plex = callPackage ../servers/plex { };
 
   plexRaw = callPackage ../servers/plex/raw.nix { };