From b918680e7b5fe2ceb097eaf08f07e2c4641e92b7 Mon Sep 17 00:00:00 2001
From: aleksana <me@aleksana.moe>
Date: Tue, 18 Jun 2024 22:27:32 +0800
Subject: [PATCH] syndication-domination: init at 1.0-unstable-2023-03-25

---
 .../sy/syndication-domination/package.nix     | 55 +++++++++++++++++++
 pkgs/top-level/python-packages.nix            |  5 ++
 2 files changed, 60 insertions(+)
 create mode 100644 pkgs/by-name/sy/syndication-domination/package.nix

diff --git a/pkgs/by-name/sy/syndication-domination/package.nix b/pkgs/by-name/sy/syndication-domination/package.nix
new file mode 100644
index 000000000000..10e325d85642
--- /dev/null
+++ b/pkgs/by-name/sy/syndication-domination/package.nix
@@ -0,0 +1,55 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitLab,
+  meson,
+  ninja,
+  pkg-config,
+  pugixml,
+  fmt,
+  html-tidy,
+  enablePython? false,
+  python3Packages,
+}:
+
+stdenv.mkDerivation {
+  pname = "syndication-domination";
+  # author extraction feature needed by gnome-feeds
+  version = "1.0-unstable-2023-03-25";
+
+  src = fetchFromGitLab {
+    owner = "gabmus";
+    repo = "syndication-domination";
+    rev = "75920321062d682437f3fb0319dad227d8b18f6c";
+    hash = "sha256-fOlE9CsNcmGkVBXaqYHxLDWB8voeRp46+dZYIJIwg7o=";
+  };
+
+  nativeBuildInputs = [
+    meson
+    ninja
+    pkg-config
+  ];
+
+  buildInputs = [
+    pugixml
+    fmt
+    html-tidy
+  ] ++ lib.optionals enablePython [
+    python3Packages.python
+    python3Packages.pybind11
+  ];
+
+  mesonFlags = [
+    (lib.mesonBool "TO_JSON_BINARY" true)
+    (lib.mesonBool "PYTHON_BINDINGS" enablePython)
+  ];
+
+  meta = {
+    description = "RSS/Atom parser written in C++ with Python binding";
+    homepage = "https://gitlab.com/gabmus/syndication-domination";
+    license = lib.licenses.agpl3Only;
+    mainProgram = "SyndicationDomination";
+    maintainers = with lib.maintainers; [ aleksana ];
+    platforms = lib.platforms.all;
+  };
+}
diff --git a/pkgs/top-level/python-packages.nix b/pkgs/top-level/python-packages.nix
index 483cb05e6996..5bb5b4fdf1e7 100644
--- a/pkgs/top-level/python-packages.nix
+++ b/pkgs/top-level/python-packages.nix
@@ -14818,6 +14818,11 @@ self: super: with self; {
 
   syncer = callPackage ../development/python-modules/syncer { };
 
+  syndication-domination = toPythonModule (pkgs.syndication-domination.override {
+    enablePython = true;
+    python3Packages = self;
+  });
+
   synergy = callPackage ../development/python-modules/synergy { };
 
   synologydsm-api = callPackage ../development/python-modules/synologydsm-api { };