From 63710c9d9ed94d1baedd8df6766fd53304a8daaf Mon Sep 17 00:00:00 2001
From: Aaron Andersen <aaron@fosslib.net>
Date: Thu, 21 May 2026 15:39:53 -0400
Subject: [PATCH] ndg: init at 2.8.0

---
 pkgs/by-name/nd/ndg/package.nix | 65 +++++++++++++++++++++++++++++++++
 1 file changed, 65 insertions(+)
 create mode 100644 pkgs/by-name/nd/ndg/package.nix

diff --git a/pkgs/by-name/nd/ndg/package.nix b/pkgs/by-name/nd/ndg/package.nix
new file mode 100644
index 000000000000..ef5c17e03fc1
--- /dev/null
+++ b/pkgs/by-name/nd/ndg/package.nix
@@ -0,0 +1,65 @@
+{
+  lib,
+  rustPlatform,
+  fetchFromGitHub,
+  installShellFiles,
+  stdenv,
+  nix-update-script,
+  buildPackages,
+}:
+
+rustPlatform.buildRustPackage (finalAttrs: {
+  pname = "ndg";
+  version = "2.8.0";
+  __structuredAttrs = true;
+
+  src = fetchFromGitHub {
+    owner = "feel-co";
+    repo = "ndg";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-YIKEyzh0NFQlD0O92LQQNMoVCDwV8yw1Xz0Iu+4ZC5U=";
+  };
+
+  cargoHash = "sha256-r4lNSZuGFtNTOkIyd7skdEmA61lfbetI03tIUD+MO+Y=";
+
+  nativeBuildInputs = [ installShellFiles ];
+
+  cargoBuildFlags = [
+    "-p"
+    "ndg"
+    "-p"
+    "xtask"
+  ];
+
+  checkFlags = [
+    "--skip"
+    "test_js_commonjs_syntax"
+  ];
+
+  postInstall =
+    lib.optionalString (stdenv.hostPlatform.emulatorAvailable buildPackages) (
+      let
+        emulator = stdenv.hostPlatform.emulator buildPackages;
+      in
+      ''
+        ${emulator} $out/bin/xtask dist
+
+        installManPage dist/man/*
+        installShellCompletion --cmd ${finalAttrs.meta.mainProgram} dist/completions/*.{bash,fish,zsh}
+      ''
+    )
+    + ''
+      rm $out/bin/xtask
+    '';
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "Not A Docs Generator";
+    homepage = "https://github.com/feel-co/ndg";
+    changelog = "https://github.com/feel-co/ndg/blob/v${finalAttrs.version}/CHANGELOG.md";
+    license = lib.licenses.mpl20;
+    maintainers = [ lib.teams.feel-co ];
+    mainProgram = "ndg";
+  };
+})