From b6747f4e6f01bab4fc2c3523e44079a51b22d4d8 Mon Sep 17 00:00:00 2001
From: jopejoe1 <johannes@joens.email>
Date: Sun, 8 Sep 2024 20:54:35 +0200
Subject: [PATCH] zvbi: init at 0.2.42

---
 pkgs/by-name/zv/zvbi/package.nix | 57 ++++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)
 create mode 100644 pkgs/by-name/zv/zvbi/package.nix

diff --git a/pkgs/by-name/zv/zvbi/package.nix b/pkgs/by-name/zv/zvbi/package.nix
new file mode 100644
index 000000000000..cc48da24bb3c
--- /dev/null
+++ b/pkgs/by-name/zv/zvbi/package.nix
@@ -0,0 +1,57 @@
+{
+  autoreconfHook,
+  fetchFromGitHub,
+  gitUpdater,
+  lib,
+  libiconv,
+  stdenv,
+  testers,
+  validatePkgConfig,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "zvbi";
+  version = "0.2.42";
+
+  src = fetchFromGitHub {
+    owner = "zapping-vbi";
+    repo = "zvbi";
+    rev = "refs/tags/v${finalAttrs.version}";
+    hash = "sha256-IeSGscgz51IndX6Xbu8Kw8GcJ9MLXXFhV+4LvnVkrLE=";
+  };
+
+  nativeBuildInputs = [
+    autoreconfHook
+    validatePkgConfig
+  ];
+
+  buildInputs = lib.optional stdenv.isDarwin libiconv;
+
+  outputs = [
+    "out"
+    "dev"
+    "man"
+  ];
+
+  passthru = {
+    tests.pkg-config = testers.testMetaPkgConfig finalAttrs.finalPackage;
+    updateScript = gitUpdater { rev-prefix = "v"; };
+  };
+
+  meta = {
+    description = "Vertical Blanking Interval (VBI) utilities";
+    homepage = "https://github.com/zapping-vbi/zvbi";
+    changelog = "https://github.com/zapping-vbi/zvbi/blob/v${finalAttrs.version}/ChangeLog";
+    pkgConfigModules = [ "zvbi-0.2" ];
+    license = with lib.licenses; [
+      bsd2
+      bsd3
+      gpl2
+      gpl2Plus
+      lgpl21Plus
+      lgpl2Plus
+      mit
+    ];
+    maintainers = with lib.maintainers; [ jopejoe1 ];
+  };
+})