From b66c11dc88aa026f7336a30e73e3ff0b70b4deb3 Mon Sep 17 00:00:00 2001
From: Heitor Augusto <IAm.HeitorALN@proton.me>
Date: Sat, 21 Jun 2025 19:33:53 -0300
Subject: [PATCH] cosmic-reader: init at 0-unstable-2025-08-29

---
 pkgs/by-name/co/cosmic-reader/package.nix | 81 +++++++++++++++++++++++
 1 file changed, 81 insertions(+)
 create mode 100644 pkgs/by-name/co/cosmic-reader/package.nix

diff --git a/pkgs/by-name/co/cosmic-reader/package.nix b/pkgs/by-name/co/cosmic-reader/package.nix
new file mode 100644
index 000000000000..9197bdea2b00
--- /dev/null
+++ b/pkgs/by-name/co/cosmic-reader/package.nix
@@ -0,0 +1,81 @@
+{
+  lib,
+  stdenv,
+  rustPlatform,
+  fetchFromGitHub,
+  just,
+  libcosmicAppHook,
+  fontconfig,
+  freetype,
+  gumbo,
+  harfbuzz,
+  jbig2dec,
+  lcms2,
+  leptonica,
+  libjpeg,
+  openjpeg,
+  tesseract,
+  nix-update-script,
+}:
+rustPlatform.buildRustPackage (finalAttrs: {
+  pname = "cosmic-reader";
+  version = "0-unstable-2025-08-29";
+
+  src = fetchFromGitHub {
+    owner = "pop-os";
+    repo = "cosmic-reader";
+    rev = "b877809273243f0630b250fd60f12fff48e0bd22";
+    hash = "sha256-kJApZgQkHDP6lD9E2vPLyVGQ0o/xibm83N9CfIJAd0A=";
+  };
+
+  cargoHash = "sha256-4ofAtZN3FpYwNahinldALbdEJA5lDwa+CUsVIISnSTc=";
+
+  nativeBuildInputs = [
+    just
+    libcosmicAppHook
+    rustPlatform.bindgenHook
+  ];
+
+  buildInputs = [
+    fontconfig
+    freetype
+    gumbo
+    harfbuzz
+    jbig2dec
+    lcms2
+    leptonica
+    libjpeg
+    openjpeg
+    tesseract
+  ];
+
+  dontUseJustBuild = true;
+  dontUseJustCheck = true;
+
+  justFlags = [
+    "--set"
+    "prefix"
+    (placeholder "out")
+    "--set"
+    "cargo-target-dir"
+    "target/${stdenv.hostPlatform.rust.cargoShortTarget}"
+  ];
+
+  env.VERGEN_GIT_SHA = finalAttrs.src.rev;
+
+  passthru.updateScript = nix-update-script {
+    extraArgs = [
+      "--version"
+      "branch=HEAD"
+    ];
+  };
+
+  meta = {
+    description = "PDF reader for the COSMIC Desktop Environment";
+    homepage = "https://github.com/pop-os/cosmic-reader";
+    license = lib.licenses.gpl3Only;
+    mainProgram = "cosmic-reader";
+    platforms = lib.platforms.linux;
+    teams = [ lib.teams.cosmic ];
+  };
+})