diff --git a/pkgs/development/python-modules/pyobjc-framework-ApplicationServices/default.nix b/pkgs/development/python-modules/pyobjc-framework-ApplicationServices/default.nix
new file mode 100644
index 000000000000..c6df11fc9dc4
--- /dev/null
+++ b/pkgs/development/python-modules/pyobjc-framework-ApplicationServices/default.nix
@@ -0,0 +1,62 @@
+{
+  buildPythonPackage,
+  setuptools,
+  darwin,
+  pyobjc-core,
+  pyobjc-framework-Cocoa,
+  pyobjc-framework-Quartz,
+  pyobjc-framework-CoreText,
+  lib,
+}:
+
+buildPythonPackage rec {
+  pname = "pyobjc-framework-ApplicationServices";
+  pyproject = true;
+
+  inherit (pyobjc-core) version src;
+
+  sourceRoot = "${src.name}/pyobjc-framework-ApplicationServices";
+
+  build-system = [ setuptools ];
+
+  buildInputs = [ darwin.libffi ];
+
+  nativeBuildInputs = [
+    darwin.DarwinTools # sw_vers
+  ];
+
+  # Same workaround as pyobjc-framework-Quartz; see
+  # https://github.com/ronaldoussoren/pyobjc/pull/641.
+  postPatch = ''
+    substituteInPlace pyobjc_setup.py \
+      --replace-fail "-buildversion" "-buildVersion" \
+      --replace-fail "-productversion" "-productVersion" \
+      --replace-fail "/usr/bin/sw_vers" "sw_vers" \
+      --replace-fail "/usr/bin/xcrun" "xcrun"
+  '';
+
+  dependencies = [
+    pyobjc-core
+    pyobjc-framework-Cocoa
+    pyobjc-framework-Quartz
+    pyobjc-framework-CoreText
+  ];
+
+  env.NIX_CFLAGS_COMPILE = toString [
+    "-I${darwin.libffi.dev}/include"
+    "-Wno-error=unused-command-line-argument"
+  ];
+
+  pythonImportsCheck = [
+    "ApplicationServices"
+    "HIServices"
+  ];
+
+  meta = {
+    description = "PyObjC wrappers for the ApplicationServices framework on macOS";
+    homepage = "https://github.com/ronaldoussoren/pyobjc";
+    license = lib.licenses.mit;
+    platforms = lib.platforms.darwin;
+    maintainers = with lib.maintainers; [ l1n ];
+  };
+}
diff --git a/pkgs/top-level/python-packages.nix b/pkgs/top-level/python-packages.nix
index 8fa5efad605b..1a9228eebdcd 100644
--- a/pkgs/top-level/python-packages.nix
+++ b/pkgs/top-level/python-packages.nix
@@ -14754,6 +14754,10 @@ self: super: with self; {
 
   pyobjc-core = callPackage ../development/python-modules/pyobjc-core { };
 
+  pyobjc-framework-ApplicationServices =
+    callPackage ../development/python-modules/pyobjc-framework-ApplicationServices
+      { };
+
   pyobjc-framework-Cocoa = callPackage ../development/python-modules/pyobjc-framework-Cocoa { };
 
   pyobjc-framework-CoreAudio =