From b4aac7e404dff3d34bfb8b3d806cc9d5b63411d6 Mon Sep 17 00:00:00 2001
From: Kiran Shila <me@kiranshila.com>
Date: Tue, 26 Aug 2025 22:31:54 -0700
Subject: [PATCH] supernovas: init at 1.5.0

Update pkgs/by-name/su/supernovas/package.nix

Co-authored-by: Angel J <78835633+Iamanaws@users.noreply.github.com>
---
 pkgs/by-name/su/supernovas/package.nix | 39 ++++++++++++++++++++++++++
 1 file changed, 39 insertions(+)
 create mode 100644 pkgs/by-name/su/supernovas/package.nix

diff --git a/pkgs/by-name/su/supernovas/package.nix b/pkgs/by-name/su/supernovas/package.nix
new file mode 100644
index 000000000000..2fa6d8f09094
--- /dev/null
+++ b/pkgs/by-name/su/supernovas/package.nix
@@ -0,0 +1,39 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+  calceph,
+  withCalceph ? true,
+}:
+stdenv.mkDerivation (finalAttrs: {
+  pname = "supernovas";
+  version = "1.5.0";
+
+  src = fetchFromGitHub {
+    owner = "smithsonian";
+    repo = "supernovas";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-hv+OdLTzGp8y1yovZF+sSXiUi7bJx+a1V2ldsAHG9ME=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+  ];
+
+  buildInputs = lib.optionals withCalceph [ calceph ];
+
+  cmakeFlags = [
+    (lib.cmakeBool "BUILD_SHARED_LIBS" (!stdenv.hostPlatform.isStatic))
+    (lib.cmakeBool "ENABLE_CALCEPH" withCalceph)
+    (lib.cmakeBool "BUILD_EXAMPLES" false)
+  ];
+
+  meta = {
+    description = "High-performance astrometry library for C/C++";
+    homepage = "https://smithsonian.github.io/SuperNOVAS/";
+    license = lib.licenses.unlicense;
+    maintainers = with lib.maintainers; [ kiranshila ];
+    platforms = lib.platforms.all;
+  };
+})