From 785d3609240bbe07e5b6ad5b0d8e702b4d94f95d Mon Sep 17 00:00:00 2001
From: phanirithvij <phanirithvij2000@gmail.com>
Date: Fri, 12 Jun 2026 13:53:35 +0530
Subject: [PATCH] kip: init at 0.15.0

Signed-off-by: phanirithvij <phanirithvij2000@gmail.com>

Signed-off-by: phanirithvij <phanirithvij2000@gmail.com>
---
 pkgs/by-name/ki/kip/package.nix | 98 +++++++++++++++++++++++++++++++++
 1 file changed, 98 insertions(+)
 create mode 100644 pkgs/by-name/ki/kip/package.nix

diff --git a/pkgs/by-name/ki/kip/package.nix b/pkgs/by-name/ki/kip/package.nix
new file mode 100644
index 000000000000..a1a7d2a7863c
--- /dev/null
+++ b/pkgs/by-name/ki/kip/package.nix
@@ -0,0 +1,98 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitLab,
+  arpa2cm,
+  arpa2common,
+  bison,
+  cacert,
+  cmake,
+  cyrus_sasl,
+  e2fsprogs,
+  flex,
+  freediameter,
+  gnutls,
+  json_c,
+  libev,
+  libkrb5,
+  libressl,
+  openssl,
+  pkg-config,
+  python3,
+  quick-sasl,
+  quickder,
+  quickmem,
+  unbound,
+  nix-update-script,
+}:
+let
+  python-with-packages = python3.withPackages (
+    ps: with ps; [
+      asn1ate
+      colored
+      pyparsing
+      setuptools
+      six
+    ]
+  );
+in
+stdenv.mkDerivation (finalAttrs: {
+  pname = "kip";
+  version = "0.15.0";
+
+  src = fetchFromGitLab {
+    owner = "arpa2";
+    repo = "kip";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-A+tPaImjd9j1Vq69Dgh3j86xI/OcovwTZSULLkOVZaI=";
+  };
+
+  strictDeps = true;
+  __structuredAttrs = true;
+
+  nativeBuildInputs = [
+    bison
+    cacert
+    cmake
+    cyrus_sasl
+    flex
+    libkrb5
+    openssl
+    pkg-config
+  ];
+
+  buildInputs = [
+    arpa2cm
+    arpa2common
+    cyrus_sasl
+    e2fsprogs
+    freediameter
+    gnutls
+    json_c
+    libev
+    libkrb5
+    libressl
+    python-with-packages
+    quick-sasl
+    quickder
+    quickmem
+    unbound
+  ];
+
+  cmakeFlags = [
+    (lib.cmakeFeature "freeDiameter_EXTENSION_DIR" "${placeholder "out"}/lib/freeDiameter")
+  ];
+
+  preBuild = ''
+    patchShebangs test
+  '';
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "Keyful Identity Protocol — symmetric-key encryption and signing via an online KIP Service";
+    homepage = "https://gitlab.com/arpa2/kip";
+    license = lib.licenses.bsd2;
+    teams = with lib.teams; [ ngi ];
+  };
+})