From c49cfc7bee7d547daabcea8d911b2249bf58d83f Mon Sep 17 00:00:00 2001
From: t4ccer <t4ccer@gmail.com>
Date: Sun, 21 Jan 2024 19:16:35 -0700
Subject: [PATCH] gambit-project: init at 16.1.1

---
 pkgs/by-name/ga/gambit-project/package.nix | 42 ++++++++++++++++++++++
 1 file changed, 42 insertions(+)
 create mode 100644 pkgs/by-name/ga/gambit-project/package.nix

diff --git a/pkgs/by-name/ga/gambit-project/package.nix b/pkgs/by-name/ga/gambit-project/package.nix
new file mode 100644
index 000000000000..8d34ac8dfe8a
--- /dev/null
+++ b/pkgs/by-name/ga/gambit-project/package.nix
@@ -0,0 +1,42 @@
+{ lib
+, autoreconfHook
+, fetchFromGitHub
+, stdenv
+, wxGTK31
+, darwin
+, withGui ? true
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "gambit-project";
+  version = "16.1.1";
+
+  src = fetchFromGitHub {
+    owner = "gambitproject";
+    repo = "gambit";
+    rev = "v${finalAttrs.version}";
+    hash = "sha256-ElPzJDQ1q+i1OyliychSUA9pT6yGSwjn/sKV0JX5wrQ=";
+  };
+
+  nativeBuildInputs =
+    [ autoreconfHook ]
+    ++ lib.optional withGui wxGTK31;
+
+  buildInputs =
+    lib.optional withGui wxGTK31
+    ++ lib.optional stdenv.isDarwin darwin.apple_sdk.frameworks.Cocoa;
+
+  strictDeps = true;
+
+  configureFlags = [
+    (lib.enableFeature withGui "gui")
+  ];
+
+  meta = {
+    description = "An open-source collection of tools for doing computation in game theory";
+    homepage = "http://www.gambit-project.org";
+    license = lib.licenses.gpl2Only;
+    maintainers = with lib.maintainers; [ t4ccer ];
+    platforms = with lib.platforms; unix ++ windows;
+  };
+})