From affd28f5393be36499d86221851fe136cec3323e Mon Sep 17 00:00:00 2001
From: Christoph Honal <christoph.honal@web.de>
Date: Thu, 1 Feb 2024 11:57:03 +0100
Subject: [PATCH] vsmartcard-vpcd: init at 0.9-unstable-2025-01-25

---
 pkgs/by-name/vs/vsmartcard-vpcd/package.nix | 63 +++++++++++++++++++++
 1 file changed, 63 insertions(+)
 create mode 100644 pkgs/by-name/vs/vsmartcard-vpcd/package.nix

diff --git a/pkgs/by-name/vs/vsmartcard-vpcd/package.nix b/pkgs/by-name/vs/vsmartcard-vpcd/package.nix
new file mode 100644
index 000000000000..d4fcf0d63f18
--- /dev/null
+++ b/pkgs/by-name/vs/vsmartcard-vpcd/package.nix
@@ -0,0 +1,63 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  pkg-config,
+  libtool,
+  autoreconfHook,
+  pcsclite,
+  qrencode,
+  python3,
+  help2man,
+  darwin,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "vsmartcard-vpcd";
+  version = "0.9-unstable-2025-01-25";
+
+  src = fetchFromGitHub {
+    owner = "frankmorgner";
+    repo = "vsmartcard";
+    rev = "7369dae26bcb709845003ae2128b8db9df7031ae";
+    hash = "sha256-mfw/Yv12ceBVZIyAKJqBh+w4otj3rYYZbJUjKRLcsr4=";
+  };
+
+  sourceRoot = "${finalAttrs.src.name}/virtualsmartcard";
+
+  nativeBuildInputs = [
+    autoreconfHook
+    libtool
+    pkg-config
+    help2man
+  ];
+
+  buildInputs =
+    [
+      pcsclite
+      qrencode
+      (python3.withPackages (
+        pp: with pp; [
+          pyscard
+          pycrypto
+          pbkdf2
+          pillow
+          gnureadline
+        ]
+      ))
+    ]
+    ++ lib.optionals stdenv.isDarwin [
+      darwin.apple_sdk.frameworks.PCSC
+    ];
+
+  configureFlags = lib.optional stdenv.isDarwin "--enable-infoplist";
+
+  meta = {
+    description = "Emulates a smart card and makes it accessible through PC/SC";
+    homepage = "http://frankmorgner.github.io/vsmartcard/virtualsmartcard/README.html";
+    license = lib.licenses.gpl3Only;
+    platforms = lib.platforms.all;
+    broken = stdenv.isDarwin;
+    maintainers = with lib.maintainers; [ stargate01 ];
+  };
+})