diff --git a/pkgs/by-name/fe/fediwall-unwrapped/package.nix b/pkgs/by-name/fe/fediwall-unwrapped/package.nix
new file mode 100644
index 000000000000..445db9bd3e5c
--- /dev/null
+++ b/pkgs/by-name/fe/fediwall-unwrapped/package.nix
@@ -0,0 +1,38 @@
+{
+  lib,
+  fetchFromGitHub,
+  buildNpmPackage,
+}:
+
+let
+  version = "1.4.0";
+in
+buildNpmPackage {
+  pname = "fediwall";
+  inherit version;
+
+  src = fetchFromGitHub {
+    owner = "defnull";
+    repo = "fediwall";
+    tag = "v${version}";
+    hash = "sha256-aEY6mO7Es+H6CNE4shj/jz47nUeEIxGijKbUscIp0pM=";
+  };
+
+  npmDepsHash = "sha256-0VQ/CBqpQNqjg3lug+AQfFVbh0KhEaGwd+cEakBr/Dc=";
+
+  installPhase = ''
+    runHook preInstall
+
+    cp -r dist $out
+
+    runHook postInstall
+  '';
+
+  meta = {
+    description = "Social media wall for the Fediverse";
+    homepage = "https://fediwall.social";
+    license = lib.licenses.agpl3Plus;
+    platforms = lib.platforms.all;
+    maintainers = with lib.maintainers; [ transcaffeine ];
+  };
+}
diff --git a/pkgs/by-name/fe/fediwall/package.nix b/pkgs/by-name/fe/fediwall/package.nix
new file mode 100644
index 000000000000..1d35b9c2c5b3
--- /dev/null
+++ b/pkgs/by-name/fe/fediwall/package.nix
@@ -0,0 +1,25 @@
+{
+  lib,
+  stdenv,
+  fediwall-unwrapped,
+  conf ? { },
+}:
+
+if (conf == { }) then
+  fediwall-unwrapped
+else
+  stdenv.mkDerivation {
+    pname = "fediwall";
+    inherit (fediwall-unwrapped) version meta;
+
+    dontUnpack = true;
+
+    installPhase = ''
+      runHook preInstall
+      mkdir -p $out
+      ln -s ${fediwall-unwrapped}/* $out
+      echo ${lib.escapeShellArg (builtins.toJSON conf)} \
+          > "$out/wall-config.json"
+      runHook postInstall
+    '';
+  }