From 89f3632a848cba1ebcfe6e88b76c1c81389c12de Mon Sep 17 00:00:00 2001
From: emaryn <emaryn@users.noreply.github.com>
Date: Thu, 29 May 2025 14:31:36 +0800
Subject: [PATCH] vfox: init at 0.6.10

---
 pkgs/by-name/vf/vfox/package.nix | 51 ++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)
 create mode 100644 pkgs/by-name/vf/vfox/package.nix

diff --git a/pkgs/by-name/vf/vfox/package.nix b/pkgs/by-name/vf/vfox/package.nix
new file mode 100644
index 000000000000..c968eb983df5
--- /dev/null
+++ b/pkgs/by-name/vf/vfox/package.nix
@@ -0,0 +1,51 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+  writableTmpDirAsHomeHook,
+  nix-update-script,
+}:
+
+buildGoModule (finalAttrs: {
+  pname = "vfox";
+  version = "0.6.10";
+
+  src = fetchFromGitHub {
+    owner = "version-fox";
+    repo = "vfox";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-bH7rHhjmfXCOAv+K0HDyPAi+ZBfLllsGyhLSo8rpcl4=";
+  };
+
+  vendorHash = "sha256-TmWhzjjv+DkFHV4kEKpVYgQpI0Vl4aYvKR9QVpawrYA=";
+
+  __darwinAllowLocalNetworking = true;
+
+  nativeCheckInputs = [ writableTmpDirAsHomeHook ];
+
+  checkFlags =
+    let
+      skippedTests = [
+        # need network
+        "TestGetRequest"
+        "TestHeadRequest"
+        "TestDownloadFile"
+      ];
+    in
+    [ "-skip=^${builtins.concatStringsSep "$|^" skippedTests}$" ];
+
+  preCheck = ''
+    export CI=1
+  '';
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "Extendable version manager";
+    homepage = "https://github.com/version-fox/vfox";
+    changelog = "https://github.com/version-fox/vfox/releases/tag/v${finalAttrs.version}";
+    mainProgram = "vfox";
+    license = lib.licenses.asl20;
+    maintainers = with lib.maintainers; [ emaryn ];
+  };
+})