From ac307e9768f339eda9ef0f57bcc1289b0ea1af9e Mon Sep 17 00:00:00 2001
From: Ethan Carter Edwards <ethan@ethancedwards.com>
Date: Wed, 30 Jul 2025 17:50:26 -0400
Subject: [PATCH] steamworks: init at 0.97.2

NGI project.

Signed-off-by: Ethan Carter Edwards <ethan@ethancedwards.com>
---
 pkgs/by-name/st/steamworks/package.nix | 65 ++++++++++++++++++++++++++
 1 file changed, 65 insertions(+)
 create mode 100644 pkgs/by-name/st/steamworks/package.nix

diff --git a/pkgs/by-name/st/steamworks/package.nix b/pkgs/by-name/st/steamworks/package.nix
new file mode 100644
index 000000000000..c528c6897c95
--- /dev/null
+++ b/pkgs/by-name/st/steamworks/package.nix
@@ -0,0 +1,65 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitLab,
+  bison,
+  cmake,
+  flex,
+  arpa2cm,
+  arpa2common,
+  catch2,
+  log4cpp,
+  openldap,
+  sqlite,
+  nix-update-script,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "steamworks";
+  version = "0.97.2";
+
+  src = fetchFromGitLab {
+    owner = "arpa2";
+    repo = "steamworks";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-hD1nTyv/t7MQdopqivfSE0o4Qk1ymG8zQVg56lY+t9o=";
+  };
+
+  # src/common/logger.h:254:63: error: 'uint8_t' does not name a type
+  postPatch = ''
+    sed -i "38i #include <cstdint>" src/common/logger.h
+  '';
+
+  strictDeps = true;
+
+  nativeBuildInputs = [
+    bison
+    cmake
+    flex
+  ];
+
+  buildInputs = [
+    arpa2cm
+    arpa2common
+    flex
+    log4cpp
+    openldap
+    sqlite
+  ];
+
+  # Currently doesn't build in `Release` since a macro is messing with some code
+  # when building in `Release`.
+  cmakeBuildType = "Debug";
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "Configuration information distributed over LDAP in near realtime";
+    homepage = "https://gitlab.com/arpa2/steamworks";
+    changelog = "https://gitlab.com/arpa2/steamworks/-/blob/v${finalAttrs.version}/CHANGES";
+    license = lib.licenses.bsd2;
+    maintainers = [ lib.maintainers.ethancedwards8 ];
+    teams = [ lib.teams.ngi ];
+    platforms = lib.platforms.linux;
+  };
+})