From 971c840b909c72785141408cc141032cd6e8aef2 Mon Sep 17 00:00:00 2001
From: Edwin Hermans <edwin@madtech.cx>
Date: Tue, 29 Apr 2025 11:45:32 -0400
Subject: [PATCH 1/2] openhue-cli: init at 0.18

openhue-cli is a small utility written in Go to interact with Philips
Hue from the OpenHue Project https://www.openhue.io
---
 pkgs/by-name/op/openhue-cli/package.nix | 54 +++++++++++++++++++++++++
 1 file changed, 54 insertions(+)
 create mode 100644 pkgs/by-name/op/openhue-cli/package.nix

diff --git a/pkgs/by-name/op/openhue-cli/package.nix b/pkgs/by-name/op/openhue-cli/package.nix
new file mode 100644
index 000000000000..f7e990c8e0c8
--- /dev/null
+++ b/pkgs/by-name/op/openhue-cli/package.nix
@@ -0,0 +1,54 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+  versionCheckHook,
+  writableTmpDirAsHomeHook,
+}:
+
+buildGoModule (finalAttrs: {
+  pname = "openhue-cli";
+  version = "0.18";
+
+  src = fetchFromGitHub {
+    owner = "openhue";
+    repo = "openhue-cli";
+    tag = finalAttrs.version;
+    hash = "sha256-yIPqjKIvYk2Y9BYieqrm5QvvAHnuImXEDbI1JOy0kBA=";
+  };
+
+  vendorHash = "sha256-lqIzmtFtkfrJSrpic79Is0yGpnLUysPQLn2lp/Mh+u4=";
+
+  env.CGO_ENABLED = 0;
+
+  rev = "c37f2a910173d8c9df42b40bd6efb583307a40cc";
+
+  ldflags = [
+    "-s"
+    "-w"
+    "-X main.version=${finalAttrs.version}"
+    "-X main.commit=${finalAttrs.rev}"
+  ];
+
+  postInstall = ''
+    mv $out/bin/openhue-cli $out/bin/openhue
+  '';
+
+  doInstallCheck = true;
+  nativeInstallCheckInputs = [
+    versionCheckHook
+    writableTmpDirAsHomeHook
+  ];
+  versionCheckProgram = "${placeholder "out"}/bin/openhue";
+  versionCheckProgramArg = "version";
+  versionCheckKeepEnvironment = [ "HOME" ];
+
+  meta = {
+    changelog = "https://github.com/openhue/openhue-cli/releases/tag/${finalAttrs.version}";
+    description = "CLI for interacting with Philips Hue smart lighting systems";
+    homepage = "https://github.com/openhue/openhue-cli";
+    mainProgram = "openhue";
+    maintainers = with lib.maintainers; [ madeddie ];
+    license = lib.licenses.asl20;
+  };
+})

From a67742ffb5655a00b7fe19fb062df81e1920156b Mon Sep 17 00:00:00 2001
From: Edwin Hermans <edwin@madtech.cx>
Date: Sun, 22 Jun 2025 11:01:58 -0400
Subject: [PATCH 2/2] Possible fix for commit hash

How about this @Aleksanaa ?
---
 pkgs/by-name/op/openhue-cli/package.nix | 15 +++++++++++----
 1 file changed, 11 insertions(+), 4 deletions(-)

diff --git a/pkgs/by-name/op/openhue-cli/package.nix b/pkgs/by-name/op/openhue-cli/package.nix
index f7e990c8e0c8..ba9460010bfe 100644
--- a/pkgs/by-name/op/openhue-cli/package.nix
+++ b/pkgs/by-name/op/openhue-cli/package.nix
@@ -14,22 +14,29 @@ buildGoModule (finalAttrs: {
     owner = "openhue";
     repo = "openhue-cli";
     tag = finalAttrs.version;
-    hash = "sha256-yIPqjKIvYk2Y9BYieqrm5QvvAHnuImXEDbI1JOy0kBA=";
+    hash = "sha256-LSaHE3gdjpNea6o+D/JGvHtwvG13LbHv2pDcZhlIoEE=";
+    leaveDotGit = true;
+    postFetch = ''
+      cd "$out"
+      git rev-parse HEAD > $out/COMMIT
+      find "$out" -name .git -print0 | xargs -0 rm -rf
+    '';
   };
 
   vendorHash = "sha256-lqIzmtFtkfrJSrpic79Is0yGpnLUysPQLn2lp/Mh+u4=";
 
   env.CGO_ENABLED = 0;
 
-  rev = "c37f2a910173d8c9df42b40bd6efb583307a40cc";
-
   ldflags = [
     "-s"
     "-w"
     "-X main.version=${finalAttrs.version}"
-    "-X main.commit=${finalAttrs.rev}"
   ];
 
+  preBuild = ''
+    ldflags+=" -X main.commit=$(cat COMMIT)"
+  '';
+
   postInstall = ''
     mv $out/bin/openhue-cli $out/bin/openhue
   '';