From 637e568126e6712612481796c1f8e634b2aa28e4 Mon Sep 17 00:00:00 2001
From: Mahyar Mirrashed <mah.mirr@gmail.com>
Date: Sat, 14 Mar 2026 14:11:02 -0500
Subject: [PATCH] deadbranch: init at 0.3.0

---
 pkgs/by-name/de/deadbranch/package.nix | 55 ++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)
 create mode 100644 pkgs/by-name/de/deadbranch/package.nix

diff --git a/pkgs/by-name/de/deadbranch/package.nix b/pkgs/by-name/de/deadbranch/package.nix
new file mode 100644
index 000000000000..c377eb337e93
--- /dev/null
+++ b/pkgs/by-name/de/deadbranch/package.nix
@@ -0,0 +1,55 @@
+{
+  lib,
+  rustPlatform,
+  fetchFromGitHub,
+
+  # nativeBuildInputs
+  installShellFiles,
+
+  # nativeCheckInputs
+  gitMinimal,
+  writableTmpDirAsHomeHook,
+
+  # nativeInstallCheckInputs
+  versionCheckHook,
+}:
+
+rustPlatform.buildRustPackage (finalAttrs: {
+  pname = "deadbranch";
+  version = "0.3.0";
+
+  src = fetchFromGitHub {
+    owner = "armgabrielyan";
+    repo = "deadbranch";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-8KNo/6hdeBY8RbLlXt2gpLCk2DfvSuoeXJ0oh2NDX2s=";
+  };
+
+  cargoHash = "sha256-iY39RBA0fl/BpX6mlCH2bHuN+XsLdq4f7CTzjHz9Ots=";
+
+  nativeBuildInputs = [ installShellFiles ];
+
+  nativeCheckInputs = [
+    gitMinimal
+    writableTmpDirAsHomeHook
+  ];
+
+  postInstall = ''
+    installManPage $releaseDir/build/deadbranch-*/out/deadbranch.1
+    installShellCompletion --cmd deadbranch \
+      --bash <($out/bin/deadbranch completions bash) \
+      --fish <($out/bin/deadbranch completions fish) \
+      --zsh <($out/bin/deadbranch completions zsh)
+  '';
+
+  doInstallCheck = true;
+  nativeInstallCheckInputs = [ versionCheckHook ];
+
+  meta = {
+    description = "Clean up stale git branches safely";
+    homepage = "https://github.com/armgabrielyan/deadbranch";
+    license = lib.licenses.mit;
+    mainProgram = "deadbranch";
+    maintainers = with lib.maintainers; [ mahyarmirrashed ];
+  };
+})