From 35c4cd404e07f05f0426b71a2a3e361fb302dc99 Mon Sep 17 00:00:00 2001
From: Emily Trau <emily@downunderctf.com>
Date: Sun, 12 Jan 2025 21:02:58 +1100
Subject: [PATCH] simbaplusplus: init at 0-unstable-2024-11-05

---
 pkgs/by-name/si/simbaplusplus/package.nix | 46 +++++++++++++++++++++++
 1 file changed, 46 insertions(+)
 create mode 100644 pkgs/by-name/si/simbaplusplus/package.nix

diff --git a/pkgs/by-name/si/simbaplusplus/package.nix b/pkgs/by-name/si/simbaplusplus/package.nix
new file mode 100644
index 000000000000..9876b9ad1db7
--- /dev/null
+++ b/pkgs/by-name/si/simbaplusplus/package.nix
@@ -0,0 +1,46 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+  llvmPackages,
+  z3,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "simbaplusplus";
+  version = "0-unstable-2024-11-05";
+
+  src = fetchFromGitHub {
+    owner = "pgarba";
+    repo = "SiMBA-";
+    rev = "a030a187df0b650718b2aab18ccebc1f810e18b4";
+    hash = "sha256-h2in203bwfb7ArhoBN0PoWM6DZtxI4jSGQuSTTaBJ7A=";
+  };
+
+  postPatch = ''
+    substituteInPlace CMakeLists.txt \
+      --replace-fail ' ''${LLVM_TOOLS_BINARY_DIR}/llvm-config' " ${lib.getDev llvmPackages.libllvm}/bin/llvm-config" \
+      --replace-fail 'set(Z3_INCLUDE_DIRS “/usr/include”)' ""
+  '';
+
+  nativeBuildInputs = [
+    cmake
+  ];
+
+  buildInputs = [
+    llvmPackages.libllvm
+    z3
+  ];
+
+  doCheck = true;
+
+  meta = {
+    description = "SiMBA++ is a port of MBA Solver SiMBA to C/C++";
+    homepage = "https://github.com/pgarba/SiMBA-";
+    license = lib.licenses.gpl3Only;
+    mainProgram = "SiMBA++";
+    maintainers = with lib.maintainers; [ emilytrau ];
+    platforms = lib.platforms.unix;
+  };
+})