From 9ffdbb9971e37328d033e0ed5768ad6ed655da47 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Robert=20Sch=C3=BCtz?= <nix@dotlambda.de>
Date: Sun, 17 May 2026 22:31:16 -0700
Subject: [PATCH] python3Packages.spotapi: init at 1.2.7

---
 .../python-modules/spotapi/default.nix        | 64 +++++++++++++++++++
 pkgs/top-level/python-packages.nix            |  2 +
 2 files changed, 66 insertions(+)
 create mode 100644 pkgs/development/python-modules/spotapi/default.nix

diff --git a/pkgs/development/python-modules/spotapi/default.nix b/pkgs/development/python-modules/spotapi/default.nix
new file mode 100644
index 000000000000..77f379bca7aa
--- /dev/null
+++ b/pkgs/development/python-modules/spotapi/default.nix
@@ -0,0 +1,64 @@
+{
+  beautifulsoup4,
+  buildPythonPackage,
+  colorama,
+  fetchPypi,
+  lib,
+  pillow,
+  pymongo,
+  pyotp,
+  readerwriterlock,
+  redis,
+  requests,
+  setuptools,
+  tls-client,
+  typing-extensions,
+  validators,
+  websockets,
+}:
+
+buildPythonPackage (finalAttrs: {
+  pname = "spotapi";
+  version = "1.2.7";
+  pyproject = true;
+
+  # no tags on GitHub
+  src = fetchPypi {
+    inherit (finalAttrs) pname version;
+    hash = "sha256-x4UA65A4UvxqlDN5upHsPPa5yv8gKZw3kqLou/1xVtY=";
+  };
+
+  build-system = [ setuptools ];
+
+  dependencies = [
+    beautifulsoup4
+    colorama
+    pillow
+    pyotp
+    readerwriterlock
+    requests
+    tls-client
+    typing-extensions
+    validators
+  ]
+  # optional dependencies are always imported
+  ++ lib.concatAttrValues finalAttrs.passthru.optional-dependencies;
+
+  optional-dependencies = {
+    pymongo = [ pymongo ];
+    redis = [ redis ];
+    websocket = [ websockets ];
+  };
+
+  pythonImportsCheck = [ "spotapi" ];
+
+  # upstream has no unit tests
+  doCheck = false;
+
+  meta = {
+    description = "Python wrapper for the public & private Spotify API";
+    homepage = "https://github.com/Aran404/SpotAPI";
+    license = lib.licenses.gpl3Only;
+    maintainers = [ lib.maintainers.dotlambda ];
+  };
+})
diff --git a/pkgs/top-level/python-packages.nix b/pkgs/top-level/python-packages.nix
index 83b3268d35ec..512b3b292241 100644
--- a/pkgs/top-level/python-packages.nix
+++ b/pkgs/top-level/python-packages.nix
@@ -18563,6 +18563,8 @@ self: super: with self; {
 
   splunk-sdk = callPackage ../development/python-modules/splunk-sdk { };
 
+  spotapi = callPackage ../development/python-modules/spotapi { };
+
   spotifyaio = callPackage ../development/python-modules/spotifyaio { };
 
   spotipy = callPackage ../development/python-modules/spotipy { };