From 3488184ee710295168ebc83b1b9dce641005e9cc Mon Sep 17 00:00:00 2001
From: Farid Zakaria <farid.m.zakaria@gmail.com>
Date: Tue, 21 Oct 2025 08:37:46 -0700
Subject: [PATCH] kaitai-struct-cpp-stl-runtime: init at 0.11

Co-authored-by: Zexin Yuan <gh@yzx9.xyz>
---
 .../kaitai-struct-cpp-stl-runtime/package.nix | 73 +++++++++++++++++++
 1 file changed, 73 insertions(+)
 create mode 100644 pkgs/by-name/ka/kaitai-struct-cpp-stl-runtime/package.nix

diff --git a/pkgs/by-name/ka/kaitai-struct-cpp-stl-runtime/package.nix b/pkgs/by-name/ka/kaitai-struct-cpp-stl-runtime/package.nix
new file mode 100644
index 000000000000..07e1fb8a7eee
--- /dev/null
+++ b/pkgs/by-name/ka/kaitai-struct-cpp-stl-runtime/package.nix
@@ -0,0 +1,73 @@
+{
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+  gtest,
+  zlib,
+  copyPkgconfigItems,
+  makePkgconfigItem,
+  lib,
+  testers,
+  ctestCheckHook,
+}:
+stdenv.mkDerivation (finalAttrs: {
+  pname = "kaitai-struct-cpp-stl-runtime";
+  version = "0.11";
+
+  src = fetchFromGitHub {
+    owner = "kaitai-io";
+    repo = "kaitai_struct_cpp_stl_runtime";
+    tag = finalAttrs.version;
+    sha256 = "sha256-2glGPf08bkzvnkLpQIaG2qiy/yO+bZ14hjIaCKou2vU=";
+  };
+
+  doCheck = true;
+
+  outputs = [
+    "out"
+    "dev"
+  ];
+
+  nativeBuildInputs = [
+    cmake
+    copyPkgconfigItems
+    ctestCheckHook
+  ];
+
+  buildInputs = [
+    zlib
+    gtest
+  ];
+
+  strictDeps = true;
+
+  # https://github.com/kaitai-io/kaitai_struct_cpp_stl_runtime/issues/82
+  pkgconfigItems = [
+    (makePkgconfigItem rec {
+      name = "kaitai-struct-cpp-stl-runtime";
+      inherit (finalAttrs) version;
+      cflags = [ "-I${variables.includedir}" ];
+      libs = [
+        "-L${variables.libdir}"
+        "-lkaitai_struct_cpp_stl_runtime"
+      ];
+      variables = {
+        includedir = "${placeholder "dev"}/include";
+        libdir = "${placeholder "out"}/lib";
+      };
+      inherit (finalAttrs.meta) description;
+    })
+  ];
+
+  passthru = {
+    tests.pkg-config = testers.testMetaPkgConfig finalAttrs.finalPackage;
+  };
+
+  meta = {
+    pkgConfigModules = [ "kaitai-struct-cpp-stl-runtime" ];
+    description = "Kaitai Struct C++ STL Runtime Library";
+    homepage = "https://github.com/kaitai-io/kaitai_struct_cpp_stl_runtime";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ fzakaria ];
+  };
+})