From 994ff0fb04dbd1b2e756ea556379ba1bfc552366 Mon Sep 17 00:00:00 2001
From: andre4ik3 <andre4ik3@fastmail.com>
Date: Mon, 29 Sep 2025 01:34:56 +0000
Subject: [PATCH] cockpit-podman: init at 119.1

Co-authored-by: lucasew <lucas59356@gmail.com>
---
 pkgs/by-name/co/cockpit-podman/package.nix | 63 ++++++++++++++++++++++
 1 file changed, 63 insertions(+)
 create mode 100644 pkgs/by-name/co/cockpit-podman/package.nix

diff --git a/pkgs/by-name/co/cockpit-podman/package.nix b/pkgs/by-name/co/cockpit-podman/package.nix
new file mode 100644
index 000000000000..d4cd27c96f5c
--- /dev/null
+++ b/pkgs/by-name/co/cockpit-podman/package.nix
@@ -0,0 +1,63 @@
+{
+  lib,
+  stdenv,
+  cockpit,
+  nodejs,
+  gettext,
+  writeShellScriptBin,
+  fetchFromGitHub,
+  gitUpdater,
+  podman,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "cockpit-podman";
+  version = "119.1";
+
+  src = fetchFromGitHub {
+    owner = "cockpit-project";
+    repo = "cockpit-podman";
+    tag = finalAttrs.version;
+    hash = "sha256-XAOHkul9oh1mUJ27ghJgZLtriBGjofyoGhQ3gb7Gunc=";
+
+    fetchSubmodules = true;
+    postFetch = "cp $out/node_modules/.package-lock.json $out/package-lock.json";
+  };
+
+  buildInputs = [
+    nodejs
+    gettext
+    (writeShellScriptBin "git" "true")
+  ];
+
+  cockpitSrc = cockpit.src;
+
+  postPatch = ''
+    mkdir -p pkg; cp -r $cockpitSrc/pkg/lib pkg
+    mkdir -p test; cp -r $cockpitSrc/test/common test
+
+    substituteInPlace Makefile \
+      --replace-fail '$(MAKE) package-lock.json' 'true' \
+      --replace-fail '$(COCKPIT_REPO_FILES) | tar x' "" \
+      --replace-fail '/usr/local' "$out"
+
+    substituteInPlace src/manifest.json \
+      --replace-fail '"/lib/systemd' '"/run/current-system/sw/lib/systemd'
+
+    patchShebangs build.js
+  '';
+
+  passthru = {
+    updateScript = gitUpdater { };
+    cockpitPath = [ podman ];
+  };
+
+  meta = {
+    description = "Cockpit UI for podman containers";
+    homepage = "https://github.com/cockpit-project/cockpit-podman";
+    changelog = "https://github.com/cockpit-project/cockpit-podman/releases/tag/${finalAttrs.version}";
+    platforms = lib.platforms.linux;
+    license = [ lib.licenses.lgpl21 ];
+    teams = [ lib.teams.cockpit ];
+  };
+})