diff --git a/pkgs/development/python-modules/udtools/default.nix b/pkgs/development/python-modules/udtools/default.nix
new file mode 100644
index 000000000000..5f85c78baf29
--- /dev/null
+++ b/pkgs/development/python-modules/udtools/default.nix
@@ -0,0 +1,56 @@
+{
+  lib,
+  nix-update-script,
+  buildPythonPackage,
+  fetchFromGitHub,
+  python,
+  setuptools,
+  # dependencies
+  regex,
+  udapi,
+}:
+
+buildPythonPackage (finalAttrs: {
+  pname = "udtools";
+  version = "0.2.7";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "UniversalDependencies";
+    repo = "tools";
+    tag = "py${finalAttrs.version}";
+    hash = "sha256-P1gx6JRq1oWCXzB2uO/eCrw8ZgJ+0Y/0cvlLtj+X7SY=";
+  };
+
+  sourceRoot = "${finalAttrs.src.name}/udtools";
+
+  build-system = [ setuptools ];
+
+  dependencies = [
+    udapi
+    regex
+  ];
+
+  # pycheck tests are not enabled because they try to import packages/types
+  # that I can't seem to find anywhere on the internet.
+  # https://github.com/UniversalDependencies/tools/issues/158
+  pythonImportsCheck = [ "udtools" ];
+
+  passthru.updateScript = nix-update-script {
+    extraArgs = [ "--version-regex=py(.*)" ];
+  };
+
+  postInstall = ''
+    install -dm755 $out/${python.sitePackages}/udtools/data
+    cp $src/data/* $out/${python.sitePackages}/udtools/data
+  '';
+
+  meta = {
+    description = "Python tools for Universal Dependencies";
+    homepage = "https://universaldependencies.org/";
+    license = lib.licenses.gpl2Plus;
+    maintainers = with lib.maintainers; [
+      Stebalien
+    ];
+  };
+})
diff --git a/pkgs/top-level/python-packages.nix b/pkgs/top-level/python-packages.nix
index 1e36f903a5fa..7edeaaf57f8a 100644
--- a/pkgs/top-level/python-packages.nix
+++ b/pkgs/top-level/python-packages.nix
@@ -20421,6 +20421,8 @@ self: super: with self; {
 
   udatetime = callPackage ../development/python-modules/udatetime { };
 
+  udtools = callPackage ../development/python-modules/udtools { };
+
   ueagle = callPackage ../development/python-modules/ueagle { };
 
   ueberzug = callPackage ../development/python-modules/ueberzug {