From 9687b5e62e9179467a49fbfcc7a6517bcc2649ca Mon Sep 17 00:00:00 2001
From: Infinidoge <infinidoge@doge-inc.net>
Date: Wed, 25 May 2022 15:23:38 -0400
Subject: [PATCH] packwiz: init

---
 .../tools/games/minecraft/packwiz/default.nix | 38 +++++++++++++++++++
 pkgs/top-level/all-packages.nix               |  4 ++
 2 files changed, 42 insertions(+)
 create mode 100644 pkgs/tools/games/minecraft/packwiz/default.nix

diff --git a/pkgs/tools/games/minecraft/packwiz/default.nix b/pkgs/tools/games/minecraft/packwiz/default.nix
new file mode 100644
index 000000000000..3be2798312e7
--- /dev/null
+++ b/pkgs/tools/games/minecraft/packwiz/default.nix
@@ -0,0 +1,38 @@
+{ lib
+, buildGoModule
+, fetchFromGitHub
+, installShellFiles
+}:
+
+buildGoModule rec {
+  pname = "packwiz";
+  version = "unstable-2022-5-25";
+
+  src = fetchFromGitHub {
+    owner = "packwiz";
+    repo = "packwiz";
+    rev = "e71b63ea98283c8c1f0e03ee51ae40f452f22a61";
+    sha256 = "sha256-XwGacEVfQAduDCSMQFRw7Xnx4bND2zaV7l27B+2u5xg=";
+  };
+
+  vendorSha256 = "sha256-M9u7N4IrL0B4pPRQwQG5TlMaGT++w3ZKHZ0RdxEHPKk=";
+
+  nativeBuildInputs = [
+    installShellFiles
+  ];
+
+  postInstall = ''
+    installShellCompletion --cmd packwiz \
+      --bash <($out/bin/packwiz completion bash) \
+      --fish <($out/bin/packwiz completion fish) \
+      --zsh <($out/bin/packwiz completion zsh)
+  '';
+
+  meta = with lib; {
+    description = "A command line tool for editing and distributing Minecraft modpacks, using a git-friendly TOML format";
+    homepage = "https://packwiz.infra.link/";
+    license = licenses.mit;
+    maintainers = with maintainers; [ infinidoge ];
+    mainProgram = "packwiz";
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 19c18ed1aff6..12a84ccf139a 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -1356,6 +1356,10 @@ with pkgs;
     python = python3;
   };
 
+  packwiz = callPackage ../tools/games/minecraft/packwiz {
+    buildGoModule = buildGo118Module;
+  };
+
   pcem = callPackage ../applications/emulators/pcem { };
 
   pcsx2 = callPackage ../applications/emulators/pcsx2 {