From 3ee5dbcd66bd6c64c17eb167c111336459d2c8cb Mon Sep 17 00:00:00 2001
From: iko <mail@iko.soy>
Date: Thu, 9 Jan 2025 14:43:23 +0300
Subject: [PATCH] parseable: init at 1.7.1

Apply suggestions from code review

Co-authored-by: Felix Bargfeldt <41747605+Defelo@users.noreply.github.com>
---
 pkgs/by-name/pa/parseable/package.nix | 51 +++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)
 create mode 100644 pkgs/by-name/pa/parseable/package.nix

diff --git a/pkgs/by-name/pa/parseable/package.nix b/pkgs/by-name/pa/parseable/package.nix
new file mode 100644
index 000000000000..d501c1f4e6dd
--- /dev/null
+++ b/pkgs/by-name/pa/parseable/package.nix
@@ -0,0 +1,51 @@
+{
+  lib,
+  rdkafka,
+  pkg-config,
+  fetchFromGitHub,
+  rustPlatform,
+  fetchzip,
+  versionCheckHook,
+  nix-update-script,
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "parseable";
+  version = "1.7.1";
+
+  src = fetchFromGitHub {
+    owner = "parseablehq";
+    repo = "parseable";
+    tag = "v${version}";
+    hash = "sha256-Uoejniv6hUpxTZ6gosP+LHTo4FD+o1AlUEWopdpz5M0=";
+  };
+
+  LOCAL_ASSETS_PATH = fetchzip {
+    url = "https://github.com/parseablehq/console/releases/download/v0.9.15/build.zip";
+    hash = "sha256-T37pI7adfKPDkCETcGcZVzcYVcxROSZLDrFhV4XO4tc=";
+  };
+
+  useFetchCargoVendor = true;
+  cargoHash = "sha256-rT/ORTOPsOgYlS8VCMBXo/cjfSJYcCtJofcPEIlc/cI=";
+
+  nativeBuildInputs = [ pkg-config ];
+
+  buildInputs = [ rdkafka ];
+
+  buildFeatures = [ "rdkafka/dynamic-linking" ];
+
+  nativeInstallCheckInputs = [ versionCheckHook ];
+  versionCheckProgramArg = "--version";
+  doInstallCheck = true;
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "Disk less, cloud native database for logs, observability, security, and compliance";
+    homepage = "https://www.parseable.com";
+    changelog = "https://github.com/parseablehq/parseable/releases/tag/v${version}";
+    license = lib.licenses.agpl3Only;
+    maintainers = with lib.maintainers; [ ilyakooo0 ];
+    mainProgram = "parseable";
+  };
+}