From 8d082b97abfb0fd54dfe1193f34601030215ae8a Mon Sep 17 00:00:00 2001
From: TomaSajt <62384384+TomaSajt@users.noreply.github.com>
Date: Sat, 5 Oct 2024 11:07:47 +0200
Subject: [PATCH] blobdrop: init at 2.1

---
 pkgs/by-name/bl/blobdrop/package.nix | 61 ++++++++++++++++++++++++++++
 1 file changed, 61 insertions(+)
 create mode 100644 pkgs/by-name/bl/blobdrop/package.nix

diff --git a/pkgs/by-name/bl/blobdrop/package.nix b/pkgs/by-name/bl/blobdrop/package.nix
new file mode 100644
index 000000000000..4725edc5f327
--- /dev/null
+++ b/pkgs/by-name/bl/blobdrop/package.nix
@@ -0,0 +1,61 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+  pkg-config,
+  qt6,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "blobdrop";
+  version = "2.1";
+
+  src = fetchFromGitHub {
+    owner = "vimpostor";
+    repo = "blobdrop";
+    rev = "refs/tags/v${finalAttrs.version}";
+    hash = "sha256-o2+qtkyu2qcwXpum3KiogyO8D6aY7bRJ6y4FWQKQY/o=";
+  };
+
+  strictDeps = true;
+
+  nativeBuildInputs =
+    [
+      cmake
+      qt6.wrapQtAppsHook
+    ]
+    ++ lib.optionals stdenv.hostPlatform.isLinux [
+      pkg-config
+    ];
+
+  buildInputs =
+    [
+      qt6.qtdeclarative
+      qt6.qtsvg
+    ]
+    ++ lib.optionals stdenv.hostPlatform.isLinux [
+      qt6.qtwayland
+    ];
+
+  cmakeFlags = [
+    (lib.cmakeBool "BUILD_TESTING" finalAttrs.doCheck)
+  ];
+
+  doCheck = true;
+
+  preCheck = ''
+    export QT_QPA_PLATFORM=offscreen
+  '';
+
+  meta = {
+    broken = stdenv.hostPlatform.isDarwin;
+    changelog = "https://github.com/vimpostor/blobdrop/releases/tag/v${finalAttrs.version}";
+    description = "Drag and drop files directly out of the terminal";
+    homepage = "https://github.com/vimpostor/blobdrop";
+    license = lib.licenses.gpl3Only;
+    mainProgram = "blobdrop";
+    maintainers = with lib.maintainers; [ tomasajt ];
+    platforms = lib.platforms.all;
+  };
+})