From 8268df3e9afe38bc032d3eb3607d46b95db36d26 Mon Sep 17 00:00:00 2001
From: Carl Sverre <82591+carlsverre@users.noreply.github.com>
Date: Tue, 24 Feb 2026 16:18:10 -0800
Subject: [PATCH] snouty: init at 0.3.1

Adding snouty to nixpkgs. Snouty is a CLI for using Antithesis.
See more details about the project here: https://github.com/antithesishq/snouty

Co-authored-by: Winter M <winter@antithesis.com>
---
 pkgs/by-name/sn/snouty/package.nix | 59 ++++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)
 create mode 100644 pkgs/by-name/sn/snouty/package.nix

diff --git a/pkgs/by-name/sn/snouty/package.nix b/pkgs/by-name/sn/snouty/package.nix
new file mode 100644
index 000000000000..c79ff899a269
--- /dev/null
+++ b/pkgs/by-name/sn/snouty/package.nix
@@ -0,0 +1,59 @@
+{
+  lib,
+  rustPlatform,
+  fetchFromGitHub,
+  installShellFiles,
+  pkg-config,
+  openssl,
+  versionCheckHook,
+  nix-update-script,
+}:
+
+rustPlatform.buildRustPackage (finalAttrs: {
+  pname = "snouty";
+  version = "0.3.1";
+
+  src = fetchFromGitHub {
+    owner = "antithesishq";
+    repo = "snouty";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-YLB4A5Ol+4sZF1RB28npJZ4pVF2Y2lSMBD8QoV8wZUg=";
+  };
+
+  cargoHash = "sha256-TJy9mJSXgJQMMDK6TFOXQVU8PujMjd3k2gdlW5Kf//4=";
+
+  nativeBuildInputs = [
+    installShellFiles
+    pkg-config
+  ];
+
+  buildInputs = [
+    openssl
+  ];
+
+  env.OPENSSL_NO_VENDOR = true;
+
+  postInstall = ''
+    installShellCompletion \
+      $releaseDir/build/snouty-*/out/snouty.{bash,fish} \
+      --zsh $releaseDir/build/snouty-*/out/_snouty
+  '';
+
+  nativeInstallCheckInputs = [ versionCheckHook ];
+  versionCheckProgramArg = "version";
+  doInstallCheck = true;
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "CLI for the Antithesis API";
+    homepage = "https://github.com/antithesishq/snouty";
+    changelog = "https://github.com/antithesishq/snouty/releases/tag/v${finalAttrs.version}";
+    license = lib.licenses.asl20;
+    maintainers = with lib.maintainers; [
+      carlsverre
+      winter
+    ];
+    mainProgram = "snouty";
+  };
+})