From 7c852a7a21c8e1fee081de197db8be92884c6ffb Mon Sep 17 00:00:00 2001
From: Aaron Andersen <aaron@fosslib.net>
Date: Tue, 24 Feb 2026 22:47:20 +0000
Subject: [PATCH] dma: init at 0.14

---
 pkgs/by-name/dm/dma/package.nix | 48 +++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)
 create mode 100644 pkgs/by-name/dm/dma/package.nix

diff --git a/pkgs/by-name/dm/dma/package.nix b/pkgs/by-name/dm/dma/package.nix
new file mode 100644
index 000000000000..6478fbc3073c
--- /dev/null
+++ b/pkgs/by-name/dm/dma/package.nix
@@ -0,0 +1,48 @@
+{
+  stdenv,
+  lib,
+  fetchFromGitHub,
+  bison,
+  flex,
+  openssl,
+}:
+stdenv.mkDerivation (finalAttrs: {
+  pname = "dma";
+  version = "0.14";
+
+  src = fetchFromGitHub {
+    owner = "corecode";
+    repo = "dma";
+    tag = "v${finalAttrs.version}";
+    sha256 = "sha256-rmgEWkV/ZmOcO1J1uTMMO5tJWq8DTyT7ANRjHyWUGNw=";
+  };
+
+  nativeBuildInputs = [
+    bison
+    flex
+  ];
+
+  buildInputs = [
+    openssl
+  ];
+
+  postPatch = ''
+    substituteInPlace Makefile \
+      --replace-fail " -m 2755 -o root -g mail" "" \
+      --replace-fail " -m 4754 -o root -g mail" ""
+    substituteInPlace local.c \
+      --replace-fail "LIBEXEC_PATH" '"/run/wrappers/bin"'
+  '';
+
+  makeFlags = [
+    "PREFIX=${placeholder "out"}"
+  ];
+
+  meta = {
+    description = "Small Mail Transport Agent, designed for home and office use";
+    homepage = "https://github.com/corecode/dma";
+    license = lib.licenses.bsd2;
+    maintainers = with lib.maintainers; [ aanderse ];
+    platforms = lib.platforms.linux;
+  };
+})