diff --git a/pkgs/by-name/po/polonium/package.nix b/pkgs/by-name/po/polonium/package.nix
new file mode 100644
index 000000000000..339ac13fbc08
--- /dev/null
+++ b/pkgs/by-name/po/polonium/package.nix
@@ -0,0 +1,58 @@
+{
+  lib,
+  fetchFromGitHub,
+  buildNpmPackage,
+  kdePackages,
+}:
+
+buildNpmPackage (finalAttrs: {
+  pname = "polonium";
+  version = "1.1";
+
+  src = fetchFromGitHub {
+    owner = "zeroxoneafour";
+    repo = "polonium";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-Rn6mfn1R7K36fcLfIlt89SSfDQ8r6Ck0lHcI0H/yGWI=";
+    fetchSubmodules = true;
+  };
+
+  npmDepsHash = "sha256-9j5UxPRfFnaqDAW877TDNHH4rmN5QvzsUSeRVCjIz3g=";
+
+  __structuredAttrs = true;
+
+  dontConfigure = true;
+
+  # the installer does a bunch of stuff that fails in our sandbox, so just build here and then we
+  # manually do the install
+  buildFlags = [
+    "res"
+    "src"
+  ];
+
+  dontNpmBuild = true;
+
+  dontWrapQtApps = true;
+
+  installPhase = ''
+    runHook preInstall
+
+    mkdir -p $out/share/kwin/scripts/polonium
+    cp -a pkg/. $out/share/kwin/scripts/polonium
+
+    runHook postInstall
+  '';
+
+  meta = {
+    description = "Auto-tiler that uses KWin 6.0+ tiling functionality";
+    homepage = "https://polonium.vaughanm.xyz/";
+    downloadPage = "https://github.com/zeroxoneafour/polonium/releases";
+    changelog = "https://github.com/zeroxoneafour/polonium/releases/tag/v${finalAttrs.version}";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [
+      nelind
+      HeitorAugustoLN
+    ];
+    inherit (kdePackages.kwin.meta) platforms;
+  };
+})
diff --git a/pkgs/top-level/aliases.nix b/pkgs/top-level/aliases.nix
index a970c9b6951c..9a5e1bca41c3 100644
--- a/pkgs/top-level/aliases.nix
+++ b/pkgs/top-level/aliases.nix
@@ -1808,7 +1808,6 @@ mapAliases {
   podofo_0_10 = warnAlias "'podofo_0_10' has been renamed to 'podofo0'" podofo0; # Added 2026-05-08
   podofo_1_0 = throw "'podofo_1_0' has been deprecated in favour of 'podofo'"; # Added 2026-05-08
   polipo = throw "'polipo' has been removed as it is unmaintained upstream"; # Added 2025-05-18
-  polonium = throw "'polonium' has been removed, as Plasma 5 has reached end of life."; # Added 2026-05-01
   polyml56 = throw "'polyml56' has been deprecated in favor of polyml"; # Added 2026-06-01
   polyml57 = throw "'polyml57' has been deprecated in favor of polyml"; # Added 2026-06-01
   polypane = throw "'polypane' has been removed due to lack of maintenance in nixpkgs"; # Added 2025-06-25