From 7b271fcfabdf29b3a7fca8b764434af35f6ba412 Mon Sep 17 00:00:00 2001
From: Gaetan Lepage <gaetan@glepage.com>
Date: Mon, 28 Apr 2025 13:24:49 +0200
Subject: [PATCH] python312Packages.spsdk-mcu-link: init at 0.6.0

---
 .../python-modules/spsdk-mcu-link/default.nix | 80 +++++++++++++++++++
 pkgs/top-level/python-packages.nix            |  2 +
 2 files changed, 82 insertions(+)
 create mode 100644 pkgs/development/python-modules/spsdk-mcu-link/default.nix

diff --git a/pkgs/development/python-modules/spsdk-mcu-link/default.nix b/pkgs/development/python-modules/spsdk-mcu-link/default.nix
new file mode 100644
index 000000000000..b62f2afd508a
--- /dev/null
+++ b/pkgs/development/python-modules/spsdk-mcu-link/default.nix
@@ -0,0 +1,80 @@
+{
+  lib,
+  buildPythonPackage,
+  fetchPypi,
+
+  # build-system
+  setuptools,
+
+  # dependencies
+  hidapi,
+  pyusb,
+
+  # tests
+  click,
+  pytestCheckHook,
+  spsdk,
+  writableTmpDirAsHomeHook,
+
+  # passthru
+  spsdk-mcu-link,
+}:
+
+buildPythonPackage rec {
+  pname = "spsdk-mcu-link";
+  version = "0.6.0";
+  pyproject = true;
+
+  # Latest tag missing on GitHub
+  src = fetchPypi {
+    pname = "spsdk_mcu_link";
+    inherit version;
+    hash = "sha256-x+aOfFdD0+IfDT7LA2QlYqR7kMOwPfvlMCcZvOYnM0Q=";
+  };
+
+  build-system = [
+    setuptools
+  ];
+
+  pythonRemoveDeps = [
+    # unpackaged
+    "libusb_package"
+    "wasmtime"
+  ];
+
+  pythonRelaxDeps = [
+    "pyusb"
+  ];
+
+  dependencies = [
+    hidapi
+    pyusb
+  ];
+
+  nativeCheckInputs = [
+    click
+    pytestCheckHook
+    spsdk
+    writableTmpDirAsHomeHook
+  ];
+
+  # Cyclic dependency with spsdk
+  doCheck = false;
+
+  passthru.tests = {
+    pytest = spsdk-mcu-link.overridePythonAttrs {
+      pythonImportsCheck = [
+        "spsdk_mcu_link"
+      ];
+
+      doCheck = true;
+    };
+  };
+
+  meta = {
+    description = "Debugger probe plugin for SPSDK supporting LPC-Link/MCU-Link from NXP";
+    homepage = "https://pypi.org/project/spsdk-mcu-link";
+    license = lib.licenses.bsd3;
+    maintainers = with lib.maintainers; [ GaetanLepage ];
+  };
+}
diff --git a/pkgs/top-level/python-packages.nix b/pkgs/top-level/python-packages.nix
index eb7f4d9a94ca..409ddc395268 100644
--- a/pkgs/top-level/python-packages.nix
+++ b/pkgs/top-level/python-packages.nix
@@ -16435,6 +16435,8 @@ self: super: with self; {
 
   spsdk = callPackage ../development/python-modules/spsdk { };
 
+  spsdk-mcu-link = callPackage ../development/python-modules/spsdk-mcu-link { };
+
   spur = callPackage ../development/python-modules/spur { };
 
   spyder = callPackage ../development/python-modules/spyder { };