diff --git a/pkgs/by-name/fa/fastjar/package.nix b/pkgs/by-name/fa/fastjar/package.nix
new file mode 100644
index 000000000000..c7c0f9425195
--- /dev/null
+++ b/pkgs/by-name/fa/fastjar/package.nix
@@ -0,0 +1,54 @@
+{
+  lib,
+  callPackage,
+  fetchzip,
+  stdenv,
+  zlib,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "fastjar";
+  version = "0.98";
+
+  src = fetchzip {
+    pname = "fastjar-source";
+    inherit (finalAttrs) version;
+    url = "https://download.savannah.gnu.org/releases/fastjar/fastjar-${finalAttrs.version}.tar.gz";
+    hash = "sha256-8VyKNQaPLrXAy/UEm2QkBx56SSSoLdU/7w4IwrxbsQc=";
+  };
+
+  outputs = [
+    "out"
+    "info"
+    "man"
+  ];
+
+  buildInputs = [ zlib ];
+
+  strictDeps = true;
+
+  doCheck = true;
+
+  passthru = {
+    tests = lib.packagesFromDirectoryRecursive {
+      inherit callPackage;
+      directory = ./tests;
+    };
+  };
+
+  meta = {
+    homepage = "https://savannah.nongnu.org/projects/fastjar/";
+    description = "Fast Java archiver written in C";
+    longDescription = ''
+      FastJar is an attempt at creating a feature-for-feature copy of Sun's
+      JDK's 'jar' command.  Sun's jar (or Blackdown's for that matter) is
+      written entirely in Java which makes it dog slow.  Since FastJar is
+      written in C, it can create the same .jar file as Sun's tool in a fraction
+      of the time.
+    '';
+    license = lib.licenses.gpl2Plus;
+    mainProgram = "fastjar";
+    maintainers = with lib.maintainers; [ AndersonTorres ];
+    platforms = lib.platforms.all;
+  };
+})
diff --git a/pkgs/by-name/fa/fastjar/tests/version-fastjar.nix b/pkgs/by-name/fa/fastjar/tests/version-fastjar.nix
new file mode 100644
index 000000000000..33a654f7baf0
--- /dev/null
+++ b/pkgs/by-name/fa/fastjar/tests/version-fastjar.nix
@@ -0,0 +1,6 @@
+{ fastjar, testers }:
+
+testers.testVersion {
+  package = fastjar;
+  command = "fastjar --version";
+}
diff --git a/pkgs/by-name/fa/fastjar/tests/version-grepjar.nix b/pkgs/by-name/fa/fastjar/tests/version-grepjar.nix
new file mode 100644
index 000000000000..5ebb9467c5b2
--- /dev/null
+++ b/pkgs/by-name/fa/fastjar/tests/version-grepjar.nix
@@ -0,0 +1,6 @@
+{ fastjar, testers }:
+
+testers.testVersion {
+  package = fastjar;
+  command = "grepjar --version";
+}
diff --git a/pkgs/development/tools/java/fastjar/default.nix b/pkgs/development/tools/java/fastjar/default.nix
deleted file mode 100644
index c81df42edb11..000000000000
--- a/pkgs/development/tools/java/fastjar/default.nix
+++ /dev/null
@@ -1,31 +0,0 @@
-{ fetchurl, lib, stdenv, zlib }:
-
-stdenv.mkDerivation rec {
-  pname = "fastjar";
-  version = "0.98";
-
-  src = fetchurl {
-    url = "https://download.savannah.gnu.org/releases/fastjar/fastjar-${version}.tar.gz";
-    sha256 = "0iginbz2m15hcsa3x4y7v3mhk54gr1r7m3ghx0pg4n46vv2snmpi";
-  };
-
-  buildInputs = [ zlib ];
-
-  doCheck = true;
-
-  meta = {
-    description = "Fast Java archiver written in C";
-
-    longDescription = ''
-      Fastjar is a version of Sun's `jar' utility, written entirely in C, and
-      therefore quite a bit faster.  Fastjar can be up to 100x faster than
-      the stock `jar' program running without a JIT.
-    '';
-
-    homepage = "https://savannah.nongnu.org/projects/fastjar/";
-
-    license = lib.licenses.gpl2Plus;
-    platforms = lib.platforms.linux;
-    maintainers = [ ];
-  };
-}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 13ff80ee2fc4..e6e581ccf2d4 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -24521,8 +24521,6 @@ with pkgs;
 
   commonsMath = callPackage ../development/libraries/java/commons/math { };
 
-  fastjar = callPackage ../development/tools/java/fastjar { };
-
   httpunit = callPackage ../development/libraries/java/httpunit { };
 
   javaCup = callPackage ../development/libraries/java/cup {