From 78e61aaed0ca9413ae94c889dc24d75bf346a48b Mon Sep 17 00:00:00 2001
From: emily <ek@kyouma.net>
Date: Sun, 4 Aug 2024 13:49:37 +0200
Subject: [PATCH] vapoursynth-eedi3: init at unstable-2019-09-30

---
 pkgs/by-name/va/vapoursynth-eedi3/package.nix | 56 +++++++++++++++++++
 1 file changed, 56 insertions(+)
 create mode 100644 pkgs/by-name/va/vapoursynth-eedi3/package.nix

diff --git a/pkgs/by-name/va/vapoursynth-eedi3/package.nix b/pkgs/by-name/va/vapoursynth-eedi3/package.nix
new file mode 100644
index 000000000000..3a5f8b5de6a4
--- /dev/null
+++ b/pkgs/by-name/va/vapoursynth-eedi3/package.nix
@@ -0,0 +1,56 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  meson,
+  ninja,
+  pkg-config,
+  boost,
+  vapoursynth,
+  opencl-headers,
+  ocl-icd,
+  openclSupport ? true,
+}:
+
+stdenv.mkDerivation {
+  pname = "vapoursynth-eedi3";
+  version = "unstable-2019-09-30";
+
+  src = fetchFromGitHub {
+    owner = "HomeOfVapourSynthEvolution";
+    repo = "VapourSynth-EEDI3";
+    rev = "d11bdb37c7a7118cd095b53d9f8fbbac02a06ac0";
+    hash = "sha256-MIUf6sOnJ2uqGw3ixEHy1ijzlLFkQauwtm1vfgmYmcg=";
+  };
+
+  nativeBuildInputs = [
+    meson
+    ninja
+    pkg-config
+  ];
+
+  buildInputs =
+    [
+      boost
+      vapoursynth
+    ]
+    ++ lib.optionals openclSupport [
+      ocl-icd
+      opencl-headers
+    ];
+
+  postPatch = ''
+    substituteInPlace meson.build \
+      --replace-fail "vapoursynth_dep.get_pkgconfig_variable('libdir')" "get_option('libdir')"
+  '';
+
+  mesonFlags = [ (lib.mesonBool "opencl" openclSupport) ];
+
+  meta = {
+    description = "Filter for VapourSynth";
+    homepage = "https://github.com/HomeOfVapourSynthEvolution/VapourSynth-EEDI3";
+    license = with lib.licenses; [ gpl2Plus ];
+    maintainers = with lib.maintainers; [ snaki ];
+    platforms = lib.platforms.x86_64;
+  };
+}