From b7c2674b3c5bb0ab7585ee1149574d795176b2ad Mon Sep 17 00:00:00 2001
From: GueLaKais <koroyeldiores@gmail.com>
Date: Fri, 14 Mar 2025 11:04:37 +0100
Subject: [PATCH 1/2] maintainers: add guelakais

---
 maintainers/maintainer-list.nix | 6 ++++++
 1 file changed, 6 insertions(+)

diff --git a/maintainers/maintainer-list.nix b/maintainers/maintainer-list.nix
index 573558b933be..5f3b6bfb689f 100644
--- a/maintainers/maintainer-list.nix
+++ b/maintainers/maintainer-list.nix
@@ -9103,6 +9103,12 @@
     githubId = 39066502;
     name = "Guekka";
   };
+  guelakais = {
+    email = "koroyeldiores@gmail.com";
+    github = "Guelakais";
+    githubId = 76840985;
+    name = "GueLaKais";
+  };
   guibert = {
     email = "david.guibert@gmail.com";
     github = "dguibert";

From 14b42e61424bcd9a288ff4df2a0e894570f7393b Mon Sep 17 00:00:00 2001
From: GueLaKais <koroyeldiores@gmail.com>
Date: Fri, 14 Mar 2025 11:04:48 +0100
Subject: [PATCH 2/2] python3Packages.nglview: init at 3.1.4

---
 .../python-modules/nglview/default.nix        | 98 +++++++++++++++++++
 pkgs/top-level/python-packages.nix            |  2 +
 2 files changed, 100 insertions(+)
 create mode 100644 pkgs/development/python-modules/nglview/default.nix

diff --git a/pkgs/development/python-modules/nglview/default.nix b/pkgs/development/python-modules/nglview/default.nix
new file mode 100644
index 000000000000..d68a906e304e
--- /dev/null
+++ b/pkgs/development/python-modules/nglview/default.nix
@@ -0,0 +1,98 @@
+{
+  lib,
+  buildPythonPackage,
+  pythonOlder,
+  fetchFromGitHub,
+  nodejs,
+  notebook,
+  ipywidgets,
+  ipykernel,
+  numpy,
+  runCommand,
+  jupyter-packaging,
+  jupyter-core,
+  notebook-shim,
+  setuptools-scm,
+  writableTmpDirAsHomeHook,
+  pytestCheckHook,
+  mock,
+  pillow,
+  ase,
+}:
+let
+  nodeModules = runCommand "nglview-node-modules" { } ''
+    mkdir -p $out/node_modules/@jupyter-widgets/base
+    cat > $out/node_modules/@jupyter-widgets/base/package.json <<EOF
+    {
+      "name": "@jupyter-widgets/base",
+      "version": "4.1.1",
+      "main": "lib/index.js"
+    }
+    EOF
+  '';
+in
+buildPythonPackage rec {
+  pname = "nglview";
+  version = "3.1.4";
+  pyproject = true;
+
+  disabled = pythonOlder "3.7";
+
+  src = fetchFromGitHub {
+    owner = "nglviewer";
+    repo = "nglview";
+    tag = "v${version}";
+    hash = "sha256-QY7rn6q67noWeoLn0RU2Sn5SeJON+Br/j+aNMlK1PDo=";
+  };
+
+  build-system = [
+    nodejs
+    jupyter-packaging
+    jupyter-core
+    notebook-shim
+    setuptools-scm
+    writableTmpDirAsHomeHook
+  ];
+
+  dependencies = [
+    notebook
+    ipywidgets
+    ipykernel
+    numpy
+  ];
+
+  preBuild = ''
+    cd js
+    cp -r ${nodeModules}/node_modules .
+    cd ..
+  '';
+
+  pythonImportsCheck = [ "nglview" ];
+
+  nativeCheckInputs = [
+    pytestCheckHook
+    mock
+    pillow
+    ase
+  ];
+
+  disabledTests = [
+    # requires parmed
+    "test_show_schrodinger"
+    # requires older moviepy
+    "test_movie_maker"
+  ];
+
+  postInstall = ''
+    mkdir -p $out/share/jupyter/nbextensions
+    cp -r nglview/static $out/share/jupyter/nbextensions/nglview-js-widgets
+  '';
+
+  meta = {
+    description = "IPython/Jupyter widget to interactively view molecular structures and trajectories";
+    homepage = "https://github.com/nglviewer/nglview";
+    changelog = "https://github.com/nglviewer/nglview/releases/tag/v${version}";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ guelakais ];
+  };
+}
diff --git a/pkgs/top-level/python-packages.nix b/pkgs/top-level/python-packages.nix
index 2410fd2a0d2a..5264737ca668 100644
--- a/pkgs/top-level/python-packages.nix
+++ b/pkgs/top-level/python-packages.nix
@@ -9284,6 +9284,8 @@ self: super: with self; {
 
   ndcurves = toPythonModule (pkgs.ndcurves.override { python3Packages = self; pythonSupport = true; });
 
+  nglview = callPackage ../development/python-modules/nglview { };
+
   nomadnet = callPackage ../development/python-modules/nomadnet { };
 
   nonbloat-db = callPackage ../development/python-modules/nonbloat-db { };