From 782e108715d99f9191ed8bf7b71e20b81a166f53 Mon Sep 17 00:00:00 2001
From: Michael Daniels <mdaniels5757@gmail.com>
Date: Wed, 8 Apr 2026 20:29:33 -0400
Subject: [PATCH] knope: init at 0.22.4

---
 pkgs/by-name/kn/knope/package.nix | 53 +++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)
 create mode 100644 pkgs/by-name/kn/knope/package.nix

diff --git a/pkgs/by-name/kn/knope/package.nix b/pkgs/by-name/kn/knope/package.nix
new file mode 100644
index 000000000000..8bbfe376e23a
--- /dev/null
+++ b/pkgs/by-name/kn/knope/package.nix
@@ -0,0 +1,53 @@
+{
+  fetchFromGitHub,
+  git,
+  lib,
+  libgit2,
+  nix-update-script,
+  pkg-config,
+  rustPlatform,
+  versionCheckHook,
+}:
+
+rustPlatform.buildRustPackage (finalAttrs: {
+  pname = "knope";
+  version = "0.22.4";
+
+  src = fetchFromGitHub {
+    owner = "knope-dev";
+    repo = "knope";
+    tag = "knope/v${finalAttrs.version}";
+    hash = "sha256-2lZhetmctKSfLXd7jvepm1+Vc0db1teryx6tehEHCJM=";
+  };
+
+  cargoHash = "sha256-L7IT7nWinyWiuIwlBmGmHDyKB+o3LJBanHVFRQpWB+c=";
+
+  nativeBuildInputs = [ pkg-config ];
+
+  buildInputs = [ libgit2 ];
+
+  env.LIBGIT2_NO_VENDOR = 1;
+
+  nativeCheckInputs = [ git ];
+  nativeInstallCheckInputs = [ versionCheckHook ];
+
+  __structuredAttrs = true;
+  doInstallCheck = true;
+  strictDeps = true;
+
+  passthru.updateScript = nix-update-script {
+    extraArgs = [
+      "--version-regex"
+      "knope/v(.*)"
+    ];
+  };
+
+  meta = {
+    changelog = "https://github.com/knope-dev/knope/blob/${finalAttrs.src.tag}/CHANGELOG.md";
+    description = "Automation for changelogs and releases using conventional commits and/or changesets";
+    homepage = "https://knope.tech/";
+    mainProgram = "knope";
+    maintainers = with lib.maintainers; [ mdaniels5757 ];
+    license = lib.licenses.mit;
+  };
+})