From 1962b52ad23db471c63f044bad4ce580e9bd812f Mon Sep 17 00:00:00 2001
From: liberodark <liberodark@gmail.com>
Date: Sun, 9 Mar 2025 19:38:32 +0100
Subject: [PATCH] rlama: init at 0.1.29

---
 pkgs/by-name/rl/rlama/package.nix | 72 +++++++++++++++++++++++++++++++
 1 file changed, 72 insertions(+)
 create mode 100644 pkgs/by-name/rl/rlama/package.nix

diff --git a/pkgs/by-name/rl/rlama/package.nix b/pkgs/by-name/rl/rlama/package.nix
new file mode 100644
index 000000000000..cc83cfdeb68e
--- /dev/null
+++ b/pkgs/by-name/rl/rlama/package.nix
@@ -0,0 +1,72 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+  pkg-config,
+  makeWrapper,
+  poppler-utils,
+  tesseract,
+  catdoc,
+  python3Packages,
+  versionCheckHook,
+  nix-update-script,
+}:
+
+buildGoModule rec {
+  pname = "rlama";
+  version = "0.1.29";
+
+  src = fetchFromGitHub {
+    owner = "dontizi";
+    repo = "rlama";
+    tag = "v${version}";
+    hash = "sha256-Zaw2itvfUC+5fVHGfPQ+qWfjLzPqowAFt8kvBYHR9B0=";
+  };
+
+  vendorHash = "sha256-oJulwIMb9DpgRZFxw4/WMejrFONbCC8ni0YclS1WwT0=";
+
+  env.CGO_ENABLED = "0";
+
+  ldflags = [
+    "-s"
+    "-w"
+  ];
+
+  nativeBuildInputs = [
+    pkg-config
+    makeWrapper
+  ];
+
+  postInstall = ''
+    wrapProgram $out/bin/rlama \
+      --prefix PATH : ${
+        lib.makeBinPath [
+          poppler-utils
+          tesseract
+          catdoc
+          python3Packages.pdfminer-six
+          python3Packages.docx2txt
+          python3Packages.xlsx2csv
+        ]
+      }
+  '';
+
+  nativeInstallCheckInputs = [
+    versionCheckHook
+  ];
+  versionCheckProgramArg = [ "--version" ];
+  doInstallCheck = true;
+
+  passthru = {
+    updateScript = nix-update-script { };
+  };
+
+  meta = {
+    description = "Retrieval-Augmented Language Model Adapter";
+    homepage = "https://github.com/dontizi/rlama";
+    changelog = "https://github.com/dontizi/rlama/releases/tag/v${version}";
+    license = lib.licenses.asl20;
+    maintainers = with lib.maintainers; [ liberodark ];
+    mainProgram = "rlama";
+  };
+}