diff --git a/pkgs/development/libraries/coost/default.nix b/pkgs/development/libraries/coost/default.nix
new file mode 100644
index 000000000000..5d692edd434e
--- /dev/null
+++ b/pkgs/development/libraries/coost/default.nix
@@ -0,0 +1,37 @@
+{ lib, stdenv, fetchFromGitHub, cmake, curl, openssl, gitUpdater
+, withCurl ? true, withOpenSSL ? true }:
+
+stdenv.mkDerivation rec {
+  pname = "coost";
+  version = "3.0.0";
+
+  src = fetchFromGitHub {
+    owner = "idealvin";
+    repo = pname;
+    rev = "v${version}";
+    sha256 = "sha256-qpJh1yl0lYYszNHGo5Jkbzal2hnVzg7UUxiyg/Grva8=";
+  };
+
+  postPatch = ''
+    substituteInPlace cmake/coost.pc.in \
+      --replace '$'{exec_prefix}/@CMAKE_INSTALL_LIBDIR@ @CMAKE_INSTALL_FULL_LIBDIR@ \
+      --replace '$'{prefix}/@CMAKE_INSTALL_INCLUDEDIR@ @CMAKE_INSTALL_FULL_INCLUDEDIR@ \
+  '';
+
+  nativeBuildInputs = [ cmake ];
+  buildInputs = lib.optional withCurl curl ++ lib.optional withOpenSSL openssl;
+
+  cmakeFlags = [ "-DBUILD_SHARED_LIBS=ON" ]
+    ++ lib.optional withCurl "-DWITH_LIBCURL=ON"
+    ++ lib.optional withOpenSSL "-DWITH_OPENSSL=ON";
+
+  passthru.updateScript = gitUpdater { };
+
+  meta = with lib; {
+    description = "A tiny boost library in C++11";
+    homepage = "https://github.com/idealvin/coost";
+    license = licenses.mit;
+    maintainers = with maintainers; [ candyc1oud ];
+    platforms = platforms.unix;
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index d74e32ff8146..eb1297d31d77 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -425,6 +425,8 @@ with pkgs;
 
   containerpilot = callPackage ../applications/networking/cluster/containerpilot { };
 
+  coost = callPackage ../development/libraries/coost { };
+
   crc = callPackage ../applications/networking/cluster/crc { };
 
   coordgenlibs  = callPackage ../development/libraries/coordgenlibs { };