From 662712806f997ead0176b3f797c2fb00ed9e35c6 Mon Sep 17 00:00:00 2001
From: Austin Horstman <khaneliman12@gmail.com>
Date: Wed, 2 Aug 2023 08:57:07 -0500
Subject: [PATCH] nwg-displays: init at 0.3.7

---
 .../misc/nwg-displays/default.nix             | 59 +++++++++++++++++++
 pkgs/top-level/all-packages.nix               |  2 +
 2 files changed, 61 insertions(+)
 create mode 100644 pkgs/applications/misc/nwg-displays/default.nix

diff --git a/pkgs/applications/misc/nwg-displays/default.nix b/pkgs/applications/misc/nwg-displays/default.nix
new file mode 100644
index 000000000000..56691d3ce14a
--- /dev/null
+++ b/pkgs/applications/misc/nwg-displays/default.nix
@@ -0,0 +1,59 @@
+{ lib
+, fetchFromGitHub
+, atk
+, gdk-pixbuf
+, gobject-introspection
+, gtk-layer-shell
+, gtk3
+, pango
+, python310Packages
+, wrapGAppsHook
+}:
+
+python310Packages.buildPythonApplication rec {
+  pname = "nwg-displays";
+  version = "0.3.7";
+
+  src = fetchFromGitHub {
+    owner = "nwg-piotr";
+    repo = "nwg-displays";
+    rev = "v${version}";
+    hash = "sha256-Y405ZeOSpc1aPKEzFdvlgJgpGAi9HUR+Hvx63uYdp88=";
+  };
+
+  nativeBuildInputs = [
+    gobject-introspection
+    wrapGAppsHook
+  ];
+
+  buildInputs = [
+    gtk3
+  ];
+
+  propagatedBuildInputs = [
+    atk
+    gdk-pixbuf
+    gtk-layer-shell
+    pango
+    python310Packages.gst-python
+    python310Packages.i3ipc
+    python310Packages.pygobject3
+  ];
+
+  dontWrapGApps = true;
+
+  preFixup = ''
+    makeWrapperArgs+=("''${gappsWrapperArgs[@]}");
+  '';
+
+  # Upstream has no tests
+  doCheck = false;
+
+  meta = {
+    homepage = "https://github.com/nwg-piotr/nwg-displays";
+    description = "Output management utility for Sway and Hyprland";
+    license = lib.licenses.mit;
+    platforms = lib.platforms.linux;
+    maintainers = [ ];
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index cc48e816f647..5878a2b9b2e2 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -33670,6 +33670,8 @@ with pkgs;
 
   nwg-bar = callPackage ../applications/misc/nwg-bar { };
 
+  nwg-displays = callPackage ../applications/misc/nwg-displays { };
+
   nwg-dock = callPackage ../applications/misc/nwg-dock { };
 
   nwg-dock-hyprland = callPackage ../applications/misc/nwg-dock-hyprland { };