From 74cc2f96699f0f39ee895ae8a970a476e9e2e861 Mon Sep 17 00:00:00 2001
From: xiangpingjiang <xiangpingjiang1998@gmail.com>
Date: Thu, 29 Jan 2026 14:39:23 +0800
Subject: [PATCH] aliyunpan: init at 0.3.7

Co-authored-by: LIN, Jian <me@linj.tech>
---
 pkgs/by-name/al/aliyunpan/package.nix | 54 +++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)
 create mode 100644 pkgs/by-name/al/aliyunpan/package.nix

diff --git a/pkgs/by-name/al/aliyunpan/package.nix b/pkgs/by-name/al/aliyunpan/package.nix
new file mode 100644
index 000000000000..56c79d41749e
--- /dev/null
+++ b/pkgs/by-name/al/aliyunpan/package.nix
@@ -0,0 +1,54 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+}:
+
+buildGoModule (finalAttrs: {
+  pname = "aliyunpan";
+  version = "0.3.7";
+
+  src = fetchFromGitHub {
+    owner = "tickstep";
+    repo = "aliyunpan";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-9sbAKv2SOZPKnP56vL0rfMEDhTpIV524s9sIvlWAM6o=";
+  };
+
+  vendorHash = "sha256-tNUXB+pU/0gJL3oG9rdk6J+SvO5ASqkuO+gVZiRdaVg=";
+
+  ldflags = [
+    "-s"
+    "-w"
+    "-X main.Version=v${finalAttrs.version}"
+  ];
+
+  # skip test
+  checkFlags =
+    let
+      skippedTests = [
+        # require network access
+        "TestGetQRCodeLoginResult"
+        # depend specific local file
+        "TestBoltUltraFiles"
+        "TestLocalSyncDb"
+        "TestLocalGet"
+      ];
+    in
+    [ "-skip=^${builtins.concatStringsSep "$|^" skippedTests}$" ];
+
+  postInstall = ''
+    mkdir -p "$out/share/doc/aliyunpan"
+    cp README.md "$out/share/doc/aliyunpan/"
+    cp docs/manual.md "$out/share/doc/aliyunpan/"
+    cp docs/plugin_manual.md "$out/share/doc/aliyunpan/"
+  '';
+
+  meta = {
+    description = "Command line client for Aliyun Drive";
+    homepage = "https://github.com/tickstep/aliyunpan";
+    license = lib.licenses.asl20;
+    maintainers = with lib.maintainers; [ xiangpingjiang ];
+    mainProgram = "aliyunpan";
+  };
+})