From 742d9516f4b791dd749813e337bd3e4641a84db3 Mon Sep 17 00:00:00 2001
From: Yifei Sun <ysun@hey.com>
Date: Fri, 5 Jun 2026 14:23:25 +0200
Subject: [PATCH] nirimon: init at 2026.605.1

---
 pkgs/by-name/ni/nirimon/package.nix | 52 +++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)
 create mode 100644 pkgs/by-name/ni/nirimon/package.nix

diff --git a/pkgs/by-name/ni/nirimon/package.nix b/pkgs/by-name/ni/nirimon/package.nix
new file mode 100644
index 000000000000..43645f4ef3b3
--- /dev/null
+++ b/pkgs/by-name/ni/nirimon/package.nix
@@ -0,0 +1,52 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+  makeWrapper,
+  nix-update-script,
+  versionCheckHook,
+  wl-mirror,
+}:
+
+buildGoModule (finalAttrs: {
+  pname = "nirimon";
+  version = "2026.605.1";
+
+  __structuredAttrs = true;
+
+  src = fetchFromGitHub {
+    owner = "stepbrobd";
+    repo = "nirimon";
+    tag = finalAttrs.version;
+    hash = "sha256-mdBl2QuvAYEltGB2kE0EJhQtWSSZ78qdpSzWKreDZUY=";
+  };
+
+  vendorHash = "sha256-txuaYMyYYalKGQ5RIuPL/ERyDt/eMeo85aZSgx4HbZk=";
+
+  ldflags = [
+    "-s"
+    "-w"
+    "-X main.Version=${finalAttrs.version}"
+  ];
+
+  nativeBuildInputs = [ makeWrapper ];
+
+  postFixup = ''
+    wrapProgram $out/bin/nirimon --prefix PATH : "${lib.makeBinPath [ wl-mirror ]}"
+  '';
+
+  doInstallCheck = true;
+  nativeInstallCheckInputs = [ versionCheckHook ];
+  versionCheckProgramArg = "-version";
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "TUI monitor configuration tool for niri with visual layout, drag-and-drop, and profile management";
+    homepage = "https://github.com/stepbrobd/nirimon";
+    license = lib.licenses.asl20;
+    mainProgram = "nirimon";
+    maintainers = with lib.maintainers; [ stepbrobd ];
+    platforms = lib.platforms.linux;
+  };
+})