From 6ffd74b5365403c7cc1b2f670f89ba52d7303baf Mon Sep 17 00:00:00 2001
From: Someone Serge <sergei.kozlukov@aalto.fi>
Date: Fri, 16 Feb 2024 19:40:09 +0000
Subject: [PATCH] python3Packages.rerun-sdk: init at 0.13.0

---
 .../python-modules/rerun-sdk/default.nix      | 70 +++++++++++++++++++
 pkgs/top-level/python-packages.nix            |  2 +
 2 files changed, 72 insertions(+)
 create mode 100644 pkgs/development/python-modules/rerun-sdk/default.nix

diff --git a/pkgs/development/python-modules/rerun-sdk/default.nix b/pkgs/development/python-modules/rerun-sdk/default.nix
new file mode 100644
index 000000000000..7c6c13be63a2
--- /dev/null
+++ b/pkgs/development/python-modules/rerun-sdk/default.nix
@@ -0,0 +1,70 @@
+{
+  buildPythonPackage,
+  lib,
+  rustPlatform,
+  stdenv,
+  attrs,
+  numpy,
+  pillow,
+  pyarrow,
+  rerun,
+  torch,
+  typing-extensions,
+  pytestCheckHook,
+  python,
+}:
+
+buildPythonPackage {
+  pname = "rerun-sdk";
+  inherit (rerun) version;
+  pyproject = true;
+
+  inherit (rerun) src;
+  inherit (rerun) cargoDeps;
+
+  nativeBuildInputs = [
+    rustPlatform.cargoSetupHook
+    rustPlatform.maturinBuildHook
+  ];
+
+  propagatedBuildInputs = [
+    attrs
+    numpy
+    pillow
+    pyarrow
+    typing-extensions
+  ];
+
+  buildAndTestSubdir = "rerun_py";
+
+  # https://github.com/NixOS/nixpkgs/issues/289340
+  #
+  # Alternatively, one could
+  # dontUsePythonImportsCheck = true;
+  # dontUsePytestCheck = true;
+  postInstall = ''
+    rm $out/${python.sitePackages}/rerun_sdk.pth
+    ln -s rerun_sdk/rerun $out/${python.sitePackages}/rerun
+  '';
+
+  pythonImportsCheck = [ "rerun" ];
+
+  nativeCheckInputs = [
+    pytestCheckHook
+    torch
+  ];
+
+  inherit (rerun) addBuildInputRunpathsPhase;
+  postPhases = lib.optionals stdenv.isLinux [ "addBuildInputRunpathsPhase" ];
+
+  disabledTestPaths = [
+    # "fixture 'benchmark' not found"
+    "tests/python/log_benchmark/test_log_benchmark.py"
+  ];
+
+  meta = {
+    description = "Python bindings for `rerun` (an interactive visualization tool for stream data)";
+    inherit (rerun.meta) changelog homepage license maintainers;
+    mainProgram = "rerun";
+  };
+}
diff --git a/pkgs/top-level/python-packages.nix b/pkgs/top-level/python-packages.nix
index 92354bbb789b..690b6a162950 100644
--- a/pkgs/top-level/python-packages.nix
+++ b/pkgs/top-level/python-packages.nix
@@ -12662,6 +12662,8 @@ self: super: with self; {
 
   reretry = callPackage ../development/python-modules/reretry { };
 
+  rerun-sdk = callPackage ../development/python-modules/rerun-sdk { };
+
   resampy = callPackage ../development/python-modules/resampy { };
 
   resize-right = callPackage ../development/python-modules/resize-right { };