From 398677c9251252c61214e7ebb66b8dbd1072d2d5 Mon Sep 17 00:00:00 2001
From: Harinn <prinn.dev@pm.me>
Date: Tue, 21 Apr 2026 02:17:17 +0700
Subject: [PATCH] pvetui: init at 1.3.2

---
 pkgs/by-name/pv/pvetui/package.nix | 43 ++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)
 create mode 100644 pkgs/by-name/pv/pvetui/package.nix

diff --git a/pkgs/by-name/pv/pvetui/package.nix b/pkgs/by-name/pv/pvetui/package.nix
new file mode 100644
index 000000000000..44f67fd7290a
--- /dev/null
+++ b/pkgs/by-name/pv/pvetui/package.nix
@@ -0,0 +1,43 @@
+{
+  lib,
+  buildGoModule,
+  fetchFromGitHub,
+  nix-update-script,
+}:
+
+buildGoModule (finalAttrs: {
+  pname = "pvetui";
+  version = "1.3.2";
+
+  __structuredAttrs = true;
+
+  src = fetchFromGitHub {
+    owner = "devnullvoid";
+    repo = "pvetui";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-PgxhfDFP0DBrihtkIWFYEOTbXUvp/WuB47iNPHJGr1Q=";
+  };
+
+  vendorHash = "sha256-gGhEW9owJYjI+59X/yJ+tta9AQh9hoBdOBaO5Rojdy8=";
+
+  subPackages = [ "cmd/pvetui" ];
+
+  ldflags = [
+    "-s"
+    "-w"
+    "-X github.com/devnullvoid/pvetui/internal/version.version=${finalAttrs.version}"
+    "-X github.com/devnullvoid/pvetui/internal/version.commit=${finalAttrs.src.tag}"
+    "-X github.com/devnullvoid/pvetui/internal/version.buildDate=1970-01-01T00:00:00Z"
+  ];
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "Terminal UI for Proxmox Virtual Environment";
+    homepage = "https://pvetui.org/";
+    changelog = "https://github.com/devnullvoid/pvetui/releases/tag/v${finalAttrs.version}";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ miniharinn ];
+    mainProgram = "pvetui";
+  };
+})