From a13bc9c0a0c47cee393f75583e54d8ba1ecdd7fe Mon Sep 17 00:00:00 2001
From: Anderson Torres <torres.anderson.85@protonmail.com>
Date: Wed, 6 Dec 2023 16:40:08 -0300
Subject: [PATCH 1/2] advcpmv: init at 0.9-9.3

---
 pkgs/by-name/ad/advcpmv/package.nix | 62 +++++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)
 create mode 100644 pkgs/by-name/ad/advcpmv/package.nix

diff --git a/pkgs/by-name/ad/advcpmv/package.nix b/pkgs/by-name/ad/advcpmv/package.nix
new file mode 100644
index 000000000000..5f9dd17f3539
--- /dev/null
+++ b/pkgs/by-name/ad/advcpmv/package.nix
@@ -0,0 +1,62 @@
+{ coreutils
+, fetchFromGitHub
+}:
+
+let
+  advcpmv-data = {
+    pname = "advcpmv";
+    patch-version = "0.9";
+    coreutils-version = "9.3";
+    version = "${advcpmv-data.patch-version}-${advcpmv-data.coreutils-version}";
+    src = fetchFromGitHub {
+      owner = "jarun";
+      repo = "advcpmv";
+      rev = "a1f8b505e691737db2f7f2b96275802c45f65c59";
+      hash = "sha256-IHfMu6PyGRPc87J/hbxMUdosmLq13K0oWa5fPLWKOvo=";
+    };
+    patch-file = advcpmv-data.src + "/advcpmv-${advcpmv-data.version}.patch";
+  };
+  coreutilsNoSingleBinary = coreutils.override { singleBinary = false; };
+in
+assert (advcpmv-data.coreutils-version == coreutils.version);
+coreutilsNoSingleBinary.overrideAttrs (old: {
+  inherit (advcpmv-data) pname version;
+
+  patches = (old.patches or [ ]) ++ [
+    advcpmv-data.patch-file
+  ];
+
+  outputs = [ "out" ]; # Since we don't need info files
+
+  configureFlags = (old.configureFlags or [ ]) ++ [
+    # To not conflict with regular coreutils
+    "--program-prefix=adv"
+  ];
+
+  # Only cpg and mvg are desired, the others are not touched and therefore can
+  # be removed. Equally, the info directory is removed.
+  postFixup = (old.postFixup or "") + ''
+    rm -rf $out/share/info
+    pushd $out/bin
+    mv advcp cpg
+    mv advmv mvg
+    rm adv*
+    mv cpg advcp
+    mv mvg advmv
+    ln -s advcp cpg
+    ln -s advcp acp
+    ln -s advmv mvg
+    ln -s advmv amv
+    popd
+  '';
+
+  meta = old.meta // {
+    homepage = "https://github.com/jarun/advcpmv";
+    description = "Patched cp and mv from Coreutils that provides progress bars";
+    longDescription = ''
+      Advanced Copy is a mod for the GNU cp and GNU mv tools which adds a
+      progress bar and provides some info on what's going on. It was written by
+      Florian Zwicke and released under the GPL.
+    '';
+  };
+})

From 4fb8db4b03e4999dd8aa1b99f107b32caf6b1d8b Mon Sep 17 00:00:00 2001
From: Anderson Torres <torres.anderson.85@protonmail.com>
Date: Wed, 20 Dec 2023 17:49:13 -0300
Subject: [PATCH 2/2] advcpmv: 0.9-9.3 -> 0.9-9.4

---
 pkgs/by-name/ad/advcpmv/package.nix | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/pkgs/by-name/ad/advcpmv/package.nix b/pkgs/by-name/ad/advcpmv/package.nix
index 5f9dd17f3539..ba4caea99cd3 100644
--- a/pkgs/by-name/ad/advcpmv/package.nix
+++ b/pkgs/by-name/ad/advcpmv/package.nix
@@ -6,7 +6,7 @@ let
   advcpmv-data = {
     pname = "advcpmv";
     patch-version = "0.9";
-    coreutils-version = "9.3";
+    coreutils-version = "9.4";
     version = "${advcpmv-data.patch-version}-${advcpmv-data.coreutils-version}";
     src = fetchFromGitHub {
       owner = "jarun";