From 6c6eb45a8de717bec85905f91ec61fc6384f7752 Mon Sep 17 00:00:00 2001
From: Sigmanificient <edhyjox@gmail.com>
Date: Fri, 26 Jul 2024 04:13:16 +0200
Subject: [PATCH] hardinfo2: init at 2.2.4

---
 pkgs/by-name/ha/hardinfo2/package.nix | 95 +++++++++++++++++++++++++++
 1 file changed, 95 insertions(+)
 create mode 100644 pkgs/by-name/ha/hardinfo2/package.nix

diff --git a/pkgs/by-name/ha/hardinfo2/package.nix b/pkgs/by-name/ha/hardinfo2/package.nix
new file mode 100644
index 000000000000..205894201b05
--- /dev/null
+++ b/pkgs/by-name/ha/hardinfo2/package.nix
@@ -0,0 +1,95 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+
+  cmake,
+  pkg-config,
+  libsForQt5,
+  wrapGAppsHook4,
+
+  gtk3,
+  json-glib,
+  lerc,
+  libdatrie,
+  libepoxy,
+  libnghttp2,
+  libpsl,
+  libselinux,
+  libsepol,
+  libsoup_3,
+  libsysprof-capture,
+  libthai,
+  libxkbcommon,
+  pcre2,
+  sqlite,
+  util-linux,
+  libXdmcp,
+  libXtst,
+}:
+
+stdenv.mkDerivation (finalAtrs: {
+  pname = "hardinfo2";
+  version = "2.2.4";
+
+  src = fetchFromGitHub {
+    owner = "hardinfo2";
+    repo = "hardinfo2";
+    rev = "refs/tags/release-${finalAtrs.version}";
+    hash = "sha256-UgVryuUkD9o2SvwA9VbX/kCaAo3+Osf6FxlYyaRX1Ag=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+    wrapGAppsHook4
+    libsForQt5.wrapQtAppsHook
+  ];
+
+  preFixup = ''
+    makeWrapperArgs+=("''${qtWrapperArgs[@]}")
+  '';
+
+  dontWrapQtApps = true;
+
+  buildInputs = [
+    gtk3
+    json-glib
+    lerc
+    libdatrie
+    libepoxy
+    libnghttp2
+    libpsl
+    libselinux
+    libsepol
+    libsoup_3
+    libsysprof-capture
+    libthai
+    libxkbcommon
+    pcre2
+    sqlite
+    util-linux
+    libXdmcp
+    libXtst
+  ];
+
+  hardeningDisable = [ "fortify" ];
+
+  cmakeFlags = [
+    (lib.cmakeFeature "CMAKE_INSTALL_DATAROOTDIR" "${placeholder "out"}/share")
+    (lib.cmakeFeature "CMAKE_INSTALL_SERVICEDIR" "${placeholder "out"}/lib")
+  ];
+
+  meta = {
+    homepage = "http://www.hardinfo2.org";
+    description = "System information and benchmarks for Linux systems";
+    license = with lib.licenses; [
+      gpl2Plus
+      gpl3Plus
+      lgpl2Plus
+    ];
+    maintainers = with lib.maintainers; [ sigmanificient ];
+    platforms = lib.platforms.linux;
+    mainProgram = "hardinfo";
+  };
+})