From 6b906cc026c0be8ddadd3d1017781ac087fcbc41 Mon Sep 17 00:00:00 2001
From: jzbor <jzbor@posteo.net>
Date: Thu, 18 Dec 2025 13:45:12 +0100
Subject: [PATCH] nix-sweep: init at 0.8.0

---
 pkgs/by-name/ni/nix-sweep/package.nix | 50 +++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)
 create mode 100644 pkgs/by-name/ni/nix-sweep/package.nix

diff --git a/pkgs/by-name/ni/nix-sweep/package.nix b/pkgs/by-name/ni/nix-sweep/package.nix
new file mode 100644
index 000000000000..6c89fc29408a
--- /dev/null
+++ b/pkgs/by-name/ni/nix-sweep/package.nix
@@ -0,0 +1,50 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  rustPlatform,
+  installShellFiles,
+}:
+
+rustPlatform.buildRustPackage (finalAttrs: {
+  pname = "nix-sweep";
+  version = "0.8.0";
+
+  src = fetchFromGitHub {
+    owner = "jzbor";
+    repo = "nix-sweep";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-C83AtqexEzx+8cNZXZyYUtg4gAUyam00IM0eXO8xOgA=";
+  };
+
+  cargoHash = "sha256-etqSdtoiSPMQLuMgBK/nnJM8dDTdmRk+MT++zu/9IjM=";
+
+  nativeBuildInputs = [
+    installShellFiles
+  ];
+
+  outputs = [
+    "out"
+    "man"
+  ];
+
+  postInstall = lib.optionalString (stdenv.buildPlatform.canExecute stdenv.hostPlatform) ''
+    mkdir ./manpages
+    $out/bin/nix-sweep man ./manpages
+    installManPage ./manpages/*
+    mkdir ./completions
+    $out/bin/nix-sweep completions ./completions
+    installShellCompletion completions/nix-sweep.{bash,fish,zsh}
+  '';
+
+  meta = {
+    description = "Utility to clean up old Nix profile generations and left-over garbage collection roots";
+    homepage = "https://github.com/jzbor/nix-sweep";
+    changelog = "https://github.com/jzbor/nix-sweep/releases/tag/v${finalAttrs.version}";
+    license = lib.licenses.mit;
+    mainProgram = "nix-sweep";
+    maintainers = with lib.maintainers; [
+      jzbor
+    ];
+  };
+})