diff --git a/pkgs/development/python-modules/pydeep2/default.nix b/pkgs/development/python-modules/pydeep2/default.nix
new file mode 100644
index 000000000000..cb0ff562013a
--- /dev/null
+++ b/pkgs/development/python-modules/pydeep2/default.nix
@@ -0,0 +1,45 @@
+{
+  lib,
+  buildPythonPackage,
+  fetchFromGitHub,
+  nix-update-script,
+  setuptools,
+  ssdeep,
+}:
+
+buildPythonPackage (finalAttrs: {
+  pname = "pydeep2";
+  version = "0.5.1";
+  pyproject = true;
+
+  __structuredAttrs = true;
+
+  src = fetchFromGitHub {
+    owner = "JakubOnderka";
+    repo = "pydeep";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-qeE+ckYIDOeXaDC3Rxh4LmS0oN+Tqvjwe2tGDDt7YgA=";
+  };
+
+  build-system = [ setuptools ];
+
+  buildInputs = [ ssdeep ];
+
+  postPatch = ''
+    substituteInPlace setup.py \
+      --replace-fail '"/usr/local/include/"' '"${ssdeep}/include"' \
+      --replace-fail '"/usr/local/lib/"' '"${ssdeep}/lib"'
+  '';
+
+  pythonImportsCheck = [ "pydeep" ];
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "Python bindings for ssdeep";
+    homepage = "https://github.com/JakubOnderka/pydeep";
+    changelog = "https://github.com/JakubOnderka/pydeep/releases/tag/${finalAttrs.src.tag}";
+    license = lib.licenses.bsd3;
+    maintainers = with lib.maintainers; [ fab ];
+  };
+})
diff --git a/pkgs/top-level/python-packages.nix b/pkgs/top-level/python-packages.nix
index 8085f85f449f..ba961d21e0ed 100644
--- a/pkgs/top-level/python-packages.nix
+++ b/pkgs/top-level/python-packages.nix
@@ -14053,6 +14053,8 @@ self: super: with self; {
 
   pydeconz = callPackage ../development/python-modules/pydeconz { };
 
+  pydeep2 = callPackage ../development/python-modules/pydeep2 { inherit (pkgs) ssdeep; };
+
   pydelijn = callPackage ../development/python-modules/pydelijn { };
 
   pydemumble = callPackage ../development/python-modules/pydemumble { };