diff --git a/pkgs/development/python-modules/langchain-groq/default.nix b/pkgs/development/python-modules/langchain-groq/default.nix
new file mode 100644
index 000000000000..8f4bdf609c6c
--- /dev/null
+++ b/pkgs/development/python-modules/langchain-groq/default.nix
@@ -0,0 +1,64 @@
+{
+  lib,
+  buildPythonPackage,
+  fetchFromGitHub,
+
+  # build-system
+  poetry-core,
+
+  # dependencies
+  langchain-core,
+  groq,
+
+  # tests
+  langchain-tests,
+  pytestCheckHook,
+}:
+
+buildPythonPackage rec {
+  pname = "langchain-groq";
+  version = "0.2.4";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "langchain-ai";
+    repo = "langchain";
+    tag = "langchain-groq==${version}";
+    hash = "sha256-hXY0xmt0rvV/AhMZTR+UxMz0ba7pJjRzBRVn6XvX6cA=";
+  };
+
+  sourceRoot = "${src.name}/libs/partners/groq";
+
+  build-system = [ poetry-core ];
+
+  pythonRelaxDeps = [ "langchain-core" ];
+
+  dependencies = [
+    langchain-core
+    groq
+  ];
+
+  nativeCheckInputs = [
+    langchain-tests
+    pytestCheckHook
+  ];
+
+  pytestFlagsArray = [ "tests/unit_tests" ];
+
+  pythonImportsCheck = [ "langchain_groq" ];
+
+  passthru = {
+    inherit (langchain-core) updateScript;
+    skipBulkUpdate = true; # Broken, see https://github.com/NixOS/nixpkgs/issues/379898
+  };
+
+  meta = {
+    changelog = "https://github.com/langchain-ai/langchain/releases/tag/langchain-groq==${version}";
+    description = "Integration package connecting Groq and LangChain";
+    homepage = "https://github.com/langchain-ai/langchain/tree/master/libs/partners/groq";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [
+      sarahec
+    ];
+  };
+}
diff --git a/pkgs/top-level/python-packages.nix b/pkgs/top-level/python-packages.nix
index d366c45cd051..1df6d26b04af 100644
--- a/pkgs/top-level/python-packages.nix
+++ b/pkgs/top-level/python-packages.nix
@@ -7117,6 +7117,8 @@ self: super: with self; {
 
   langchain-core = callPackage ../development/python-modules/langchain-core { };
 
+  langchain-groq = callPackage ../development/python-modules/langchain-groq { };
+
   langchain-huggingface = callPackage ../development/python-modules/langchain-huggingface { };
 
   langchain-mongodb = callPackage ../development/python-modules/langchain-mongodb { };