From f2702292d356120c6c3fff915d2d0738d16543c9 Mon Sep 17 00:00:00 2001
From: "Adam C. Stephens" <adam@valkor.net>
Date: Mon, 13 Apr 2026 10:27:52 -0400
Subject: [PATCH] dexter: init at 0.5.3
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Co-authored-by: Łukasz Niemier <~@hauleth.dev>
---
 pkgs/by-name/de/dexter/package.nix | 50 ++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)
 create mode 100644 pkgs/by-name/de/dexter/package.nix

diff --git a/pkgs/by-name/de/dexter/package.nix b/pkgs/by-name/de/dexter/package.nix
new file mode 100644
index 000000000000..eada6fe45cca
--- /dev/null
+++ b/pkgs/by-name/de/dexter/package.nix
@@ -0,0 +1,50 @@
+{
+  buildGoModule,
+  fetchFromGitHub,
+  installShellFiles,
+  lib,
+  stdenv,
+}:
+
+buildGoModule (finalAttrs: {
+  pname = "dexter";
+  version = "0.5.3";
+
+  src = fetchFromGitHub {
+    owner = "remoteoss";
+    repo = "dexter";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-8JjxR7Q+4OgBSIgODxIEU/0mC+bPp9Nz7uCAjfn4HiY=";
+  };
+
+  vendorHash = "sha256-1mJ4HdDCsZl/g8F+L+NrW2ACuiHe2aSheJO/1XfKAb4=";
+  proxyVendor = true;
+
+  ldflags = [
+    "-s"
+    "-w"
+  ];
+
+  nativeBuildInputs = [ installShellFiles ];
+
+  postInstall = ''
+    mv $out/bin/cmd $out/bin/dexter
+  ''
+  + lib.optionalString (stdenv.buildPlatform.canExecute stdenv.hostPlatform) ''
+    installShellCompletion --cmd dexter \
+      --bash <($out/bin/dexter completion bash) \
+      --fish <($out/bin/dexter completion fish) \
+      --zsh <($out/bin/dexter completion zsh)
+  '';
+
+  __structuredAttrs = true;
+
+  meta = {
+    description = "A fast, full-featured Elixir LSP optimized for large codebases";
+    homepage = "https://github.com/remoteoss/dexter";
+    changelog = "https://github.com/remoteoss/dexter/blob/${finalAttrs.src.rev}/CHANGELOG.md";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ adamcstephens ];
+    mainProgram = "dexter";
+  };
+})