From 63cced3917186fe11d4d773c2e533f1ea90de385 Mon Sep 17 00:00:00 2001
From: Aaron Andersen <aaron@fosslib.net>
Date: Sun, 6 Oct 2024 10:27:45 -0400
Subject: [PATCH] dinit: init at 0.19.0

---
 pkgs/by-name/di/dinit/package.nix | 51 +++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)
 create mode 100644 pkgs/by-name/di/dinit/package.nix

diff --git a/pkgs/by-name/di/dinit/package.nix b/pkgs/by-name/di/dinit/package.nix
new file mode 100644
index 000000000000..26f1ad4c7e60
--- /dev/null
+++ b/pkgs/by-name/di/dinit/package.nix
@@ -0,0 +1,51 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  m4,
+  installShellFiles,
+  util-linux,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "dinit";
+  version = "0.19.0";
+
+  src = fetchFromGitHub {
+    owner = "davmac314";
+    repo = "dinit";
+    rev = "v${version}";
+    hash = "sha256-ApB0pEFSyawNASF/rqRmhT4FLofZzYmNdNmG2FGpnnk=";
+  };
+
+  postPatch = ''
+    substituteInPlace src/shutdown.cc \
+      --replace-fail '"/bin/umount"' '"${util-linux}/bin/umount"' \
+      --replace-fail '"/sbin/swapoff"' '"${util-linux}/bin/swapoff"'
+  '';
+
+  nativeBuildInputs = [
+    m4
+    installShellFiles
+  ];
+
+  configureFlags = [
+    "--prefix=${placeholder "out"}"
+    "--sbindir=${placeholder "out"}/bin"
+  ];
+
+  postInstall = ''
+    installShellCompletion --cmd dinitctl \
+      --bash contrib/shell-completion/bash/dinitctl \
+      --fish contrib/shell-completion/fish/dinitctl.fish \
+      --zsh contrib/shell-completion/zsh/_dinit
+  '';
+
+  meta = {
+    description = "A service manager / supervision system, which can (on Linux) also function as a system manager and init";
+    homepage = "https://davmac.org/projects/dinit";
+    license = lib.licenses.asl20;
+    maintainers = with lib.maintainers; [ aanderse ];
+    platforms = lib.platforms.unix;
+  };
+}