From b3383412b09e7f1371eb55b7fc36187e7e80015a Mon Sep 17 00:00:00 2001
From: tobifroe <froeltob@pm.me>
Date: Sat, 19 Apr 2025 17:51:46 +0200
Subject: [PATCH] gefyra: init at 2.3.1

---
 pkgs/by-name/ge/gefyra/package.nix | 50 ++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)
 create mode 100644 pkgs/by-name/ge/gefyra/package.nix

diff --git a/pkgs/by-name/ge/gefyra/package.nix b/pkgs/by-name/ge/gefyra/package.nix
new file mode 100644
index 000000000000..1f3125f822a9
--- /dev/null
+++ b/pkgs/by-name/ge/gefyra/package.nix
@@ -0,0 +1,50 @@
+{
+  lib,
+  stdenv,
+  fetchzip,
+  makeWrapper,
+  docker,
+  kubectl,
+  nix-update-script,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "gefyra";
+  version = "2.3.1";
+
+  src = fetchzip {
+    url = "https://github.com/gefyrahq/gefyra/releases/download/${finalAttrs.version}/gefyra-${finalAttrs.version}-linux-amd64.zip";
+    hash = "sha256-piF/h2g9NeLbSVC5YjfcN1Hq+LWXe+Ib3LolA/vOZdw=";
+    stripRoot = false;
+  };
+
+  nativeBuildInputs = [ makeWrapper ];
+
+  installPhase = ''
+    runHook preInstall
+    install -Dm755 gefyra "$out/bin/gefyra"
+    runHook postInstall
+  '';
+
+  postInstall = ''
+    wrapProgram $out/bin/gefyra \
+      --prefix PATH : ${
+        lib.makeBinPath [
+          docker
+          kubectl
+        ]
+      }
+  '';
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "Tool to connect local containers to kubernetes clusters";
+    homepage = "https://gefyra.dev";
+    downloadPage = "https://github.com/gefyrahq/gefyra";
+    mainProgram = "gefyra";
+    license = lib.licenses.asl20;
+    maintainers = with lib.maintainers; [ tobifroe ];
+    platforms = lib.platforms.linux;
+  };
+})