From 5f6ffcb49aebf596ab1ca34cbf45ecf3ba9fcf90 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Robert=20Sch=C3=BCtz?= <nix@dotlambda.de>
Date: Sun, 10 May 2026 15:16:49 -0700
Subject: [PATCH] python3Packages.pyreqwest: init at 0.12.0

---
 .../python-modules/pyreqwest/default.nix      | 78 +++++++++++++++++++
 pkgs/top-level/python-packages.nix            |  2 +
 2 files changed, 80 insertions(+)
 create mode 100644 pkgs/development/python-modules/pyreqwest/default.nix

diff --git a/pkgs/development/python-modules/pyreqwest/default.nix b/pkgs/development/python-modules/pyreqwest/default.nix
new file mode 100644
index 000000000000..10b189757108
--- /dev/null
+++ b/pkgs/development/python-modules/pyreqwest/default.nix
@@ -0,0 +1,78 @@
+{
+  buildPythonPackage,
+  cacert,
+  dirty-equals,
+  docker,
+  fetchFromGitHub,
+  granian,
+  httpx,
+  lib,
+  pydantic,
+  pytest-asyncio,
+  pytestCheckHook,
+  requests-toolbelt,
+  rustPlatform,
+  starlette,
+  syrupy,
+  trustme,
+  yarl,
+}:
+
+buildPythonPackage (finalAttrs: {
+  pname = "pyreqwest";
+  version = "0.12.0";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "MarkusSintonen";
+    repo = "pyreqwest";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-o33/KkPBl4ActDV0R8KqWll6F47HPO3amHFI00rHryE=";
+  };
+
+  cargoDeps = rustPlatform.fetchCargoVendor {
+    inherit (finalAttrs) pname version src;
+    hash = "sha256-+flEikEImbiu/x+pJQz3rynYKmfjaS9N0/A1HSzH0jU=";
+  };
+
+  build-system = [
+    rustPlatform.cargoSetupHook
+    rustPlatform.maturinBuildHook
+  ];
+
+  pythonImportsCheck = [ "pyreqwest" ];
+
+  nativeCheckInputs = [
+    dirty-equals
+    docker
+    granian
+    httpx
+    pydantic
+    pytest-asyncio
+    pytestCheckHook
+    requests-toolbelt
+    starlette
+    syrupy
+    trustme
+    yarl
+  ];
+
+  preCheck = ''
+    # Without this tests fails with
+    #     unexpected error: No CA certificates were loaded from the system
+    export SSL_CERT_FILE="${cacert}/etc/ssl/certs/ca-bundle.crt"
+  '';
+
+  disabledTestPaths = [
+    # requires a running Docker daemon
+    "tests/test_examples.py"
+  ];
+
+  meta = {
+    changelog = "https://github.com/MarkusSintonen/pyreqwest/releases/tag/${finalAttrs.src.tag}";
+    description = "Fast Python HTTP client based on Rust reqwest";
+    homepage = "https://github.com/MarkusSintonen/pyreqwest";
+    license = lib.licenses.asl20;
+    maintainers = [ lib.maintainers.dotlambda ];
+  };
+})
diff --git a/pkgs/top-level/python-packages.nix b/pkgs/top-level/python-packages.nix
index dcd84157257b..a4351da63580 100644
--- a/pkgs/top-level/python-packages.nix
+++ b/pkgs/top-level/python-packages.nix
@@ -14948,6 +14948,8 @@ self: super: with self; {
 
   pyrepetierng = callPackage ../development/python-modules/pyrepetierng { };
 
+  pyreqwest = callPackage ../development/python-modules/pyreqwest { };
+
   pyrevolve = callPackage ../development/python-modules/pyrevolve { };
 
   pyrfc3339 = callPackage ../development/python-modules/pyrfc3339 { };