From 565893559c26748b059c7987b51d83503cd54ac0 Mon Sep 17 00:00:00 2001
From: Zhong Jianxin <azuwis@gmail.com>
Date: Sat, 11 Jan 2025 11:02:28 +0800
Subject: [PATCH] uchmviewer: init at 8.4

Description: CHM (Winhelp) files viewer (fork of KchmViewer)

Homepage: https://github.com/eBookProjects/uChmViewer
---
 pkgs/by-name/uc/uchmviewer/package.nix | 56 ++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)
 create mode 100644 pkgs/by-name/uc/uchmviewer/package.nix

diff --git a/pkgs/by-name/uc/uchmviewer/package.nix b/pkgs/by-name/uc/uchmviewer/package.nix
new file mode 100644
index 000000000000..30996a7a63aa
--- /dev/null
+++ b/pkgs/by-name/uc/uchmviewer/package.nix
@@ -0,0 +1,56 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  chmlib,
+  libzip,
+  qt6,
+  cmake,
+  nix-update-script,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "uchmviewer";
+  version = "8.4";
+
+  src = fetchFromGitHub {
+    owner = "eBookProjects";
+    repo = "uChmViewer";
+    tag = "v${finalAttrs.version}";
+    hash = "sha256-p3KIIg2B+sSlwJr1rNMP7JByxYXyYFsj+UyUiDbJge8=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    qt6.wrapQtAppsHook
+  ];
+
+  buildInputs = [
+    chmlib
+    libzip
+    qt6.qt5compat
+    qt6.qtwebengine
+  ];
+
+  cmakeFlags = [
+    (lib.cmakeBool "USE_WEBENGINE" true)
+  ];
+
+  postInstall = lib.optionalString stdenv.hostPlatform.isDarwin ''
+    mkdir -p $out/{Applications,bin}
+    mv $out/uchmviewer.app $out/Applications
+    ln -s $out/Applications/uchmviewer.app/Contents/MacOS/uchmviewer $out/bin/uchmviewer
+  '';
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    changelog = "https://github.com/eBookProjects/uChmViewer/releases/tag/v${finalAttrs.version}";
+    description = "CHM (Winhelp) files viewer (fork of KchmViewer)";
+    homepage = "https://github.com/eBookProjects/uChmViewer";
+    license = lib.licenses.gpl3Plus;
+    mainProgram = "uchmviewer";
+    maintainers = with lib.maintainers; [ azuwis ];
+    platforms = lib.platforms.unix;
+  };
+})